DHCP选项集与DNS主机名

控制台

1. 前往内网 DNS 解析控制台，单击添加域名（Zone），配置自定义的内置权威域名（Zone），并设置域名生效范围为目标 VPC。

   单击目标域名 ID，您可以在ECS主机名页签，单击添加 ECS 主机名，系统将自动添加所选地域中 ECS 主机名与 IP 的域名解析记录，但主机名修改后，无法同步更新。您可以开启自动同步配置，系统将自动添加所选地域内的域名解析记录，且1分钟同步1次。如需使用自定义域名前缀，您可以选择解析记录页签，添加自定义主机记录。

2. 前往专有网络控制台 - DHCP 选项集，创建 DHCP 选项集，配置域名为对应的内置权威域名。

3. 在目标 DHCP 选项集的操作列选择关联专有网络，已配置域名解析记录的 ECS 可通过主机名/主机记录被关联 VPC 内的 ECS 访问。

API

依次调用如下 API，使用阿里云的内网 DNS 解析服务：

Terraform

当前不支持自动添加 ECS 主机名解析记录，您需要逐条添加自定义域名解析记录。

Resource：alicloud_pvtz_zone、alicloud_pvtz_zone_attachment、alicloud_pvtz_zone_record、alicloud_vpc_dhcp_options_set、alicloud_vpc_dhcp_options_set_attachment

# 指定目标VPC所在地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 配置内置权威域名
resource "alicloud_pvtz_zone" "test_pvtz_zone" {
  zone_name = "example.com"
}

# 设置域名生效范围
resource "alicloud_pvtz_zone_attachment" "test_pvtz_zone_attachment" {
  zone_id = alicloud_pvtz_zone.test_pvtz_zone.id
  vpc_ids = ["vpc-8vba******"] # 指定域名生效的VPC实例ID
}

# 添加域名解析记录
resource "alicloud_pvtz_zone_record" "test_pvtz_zone_record" {
  zone_id = alicloud_pvtz_zone.test_pvtz_zone.id
  rr      = "abc"         # 指定主机记录
  type    = "A"           # 指定域名解析记录类型
  value   = "192.168.0.4" # 指定域名解析记录值
}

# 创建DHCP选项集
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                 # 指定域名
  domain_name_servers   = "100.100.2.136,100.100.2.138" # 指定阿里云默认DNS服务器IP 
}

# 关联DHCP选项集与VPC
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vba******"                                       # 指定关联的VPC的实例ID
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # 指定关联的DHCP选项集的实例ID
}

控制台

1. 前往专有网络控制台 - DHCP 选项集，创建 DHCP 选项集，配置域名为自建 DNS 服务中使用的域名，单击自定义服务器IP，将自建 DNS 服务器 IP 填写在首位。

2. 在目标 DHCP 选项集的操作列选择关联专有网络，已配置域名解析记录的 ECS 可通过主机名被关联 VPC 内的 ECS 访问。

API

依次调用如下 API，创建自定义 DHCP 选项集指定域名与自建 DNS 服务器 IP，与 VPC 关联。

Terraform

Resource：alicloud_vpc_dhcp_options_set、alicloud_vpc_dhcp_options_set_attachment

# 指定VPC的地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 创建DHCP选项集
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                              # 指定域名
  domain_name_servers   = "192.168.0.10,100.100.2.136,100.100.2.138" # 指定DNS服务器IP，首位填写自建DNS服务器IP
}

# 关联DHCP选项集与VPC
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vbg******"                                       # 指定关联的VPC的实例ID
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # 指定关联的DHCP选项集的实例ID
}