使用Terraform配置源地址池

安装Terraform并配置权限

涉及的资源

• 创建站点：alicloud_esa_site

• 创建源地址池：alicloud_esa_origin_pool

• 查询ESA实例：alicloud_esa_sites

• 生成随机整数：random_integer

配置源地址池

1. 创建一个名为 main.tf 的配置文件，然后将以下代码复制到配置文件中，用于配置包含阿里云OSS和AWS S3两个源站的源地址池。

   # 1. 查询企业版 ESA 实例
   data "alicloud_esa_sites" "default" {
     plan_subscribe_type = "enterpriseplan"  # 筛选企业版实例
   }
   
   # 2. 生成随机数用于域名唯一性
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # 3. 创建站点
   resource "alicloud_esa_site" "default" {
     site_name   = "gositecdn-${random_integer.default.result}.cn"
     instance_id = data.alicloud_esa_sites.default.sites.0.instance_id
     coverage    = "overseas"  # 海外加速
     access_type = "NS"         # NS 接入方式
   }
   
   # 4. 创建包含多个源站的源地址池
   resource "alicloud_esa_origin_pool" "default" {
     site_id          = alicloud_esa_site.default.id
     origin_pool_name = "exampleoriginpool"
     enabled          = "true"
   
     # 源站1：阿里云 OSS
     origins {
       type    = "OSS"                                      # 源站类型：阿里云对象存储
       address = "example.oss-cn-beijing.aliyuncs.com"  # OSS Bucket 域名，请替换
       header  = "{\"Host\":[\"example.oss-cn-beijing.aliyuncs.com\"]}"  # 回源Host头
       enabled = "true"
       weight  = 50  # 流量权重50%
       name    = "origin1"
   
       # OSS 私有访问鉴权配置
       auth_conf {
         auth_type  = "private_cross_account"  # 私有跨账号访问
         access_key = "{{ACCESS_KEY}}"    # 阿里云AK（请替换为实际值）
         secret_key = "{{ACCESS_SECRET_KEY}}" # 阿里云SK（请替换为实际值）
       }
     }
   
     # 源站2：AWS S3
     origins {
       type    = "S3"               # 源站类型：AWS S3对象存储
       address = "example.s3.com"  # S3 Bucket 域名，请替换
       header  = "{\"Host\": [\"example1.com\"]}"  # 回源Host头
       enabled = "true"
       weight  = 50  # 流量权重50%
       name    = "origin2"
   
       # S3 私有访问鉴权配置
       auth_conf {
         auth_type  = "private"              # AWS S3 私有访问
         version    = "v2"                  # AWS 签名版本 2
         region     = "us-east-1"           # S3 Bucket 所在AWS区域
         access_key = "{{S3_ACCESS_KEY}}"  # AWS AK（请替换为实际值）
         secret_key = "{{S3_ACCESS_SECRET_KEY}}"  # AWS SK（请替换为实际值）
       }
     }
   }

   说明

   请根据实际情况修改代码中的占位符：将OSS和S3的 address 替换为实际Bucket域名，将 access_key 和 secret_key 替换为实际访问密钥。关键参数说明请参见本文末尾的相关参考章节。

2. 进入配置文件所在目录，执行如下命令，初始化Terraform环境。

   terraform init

3. 执行如下命令，验证Terraform语法与配置。

   terraform validate

4. 执行如下命令，预览执行结果。

   terraform plan

5. 执行如下命令，执行Terraform脚本。

   terraform apply

6. 依据提示输入yes确认执行即可。

验证结果

terraform show

相关参考

本文代码示例中关键参数的说明如下：

更多参数说明，请参见alicloud_esa_origin_pool。

不同套餐的支持情况