Terraform reference

Basic features of Terraform

Terraform is an IT infrastructure automation and orchestration tool. It lets you use code to manage and maintain IT resources. For more information, see What is Terraform?.

• The Terraform command-line interface (CLI) provides a simple way to deploy configuration files to Alibaba Cloud or other supported clouds and manage their versions. You can define your infrastructure, such as virtual machines, storage accounts, and network interfaces, in configuration files that describe your cloud resource topology.

• Terraform supports new infrastructure through providers. This lets you easily define, preview, and deploy cloud infrastructure on Alibaba Cloud using a simple template language.

• You can use Terraform to create, modify, and delete the resources of multiple Alibaba Cloud services.

For more information about the integration of Alibaba Cloud and Terraform, see Alibaba Cloud Provider.

Install Terraform

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Authenticate Terraform

You can authenticate Terraform by storing access credentials in environment variables. When you run a Terraform command, Terraform attempts to retrieve credentials from these variables if they are not explicitly declared in the configuration template. The following sections describe how to set environment variables.

# AccessKey ID
$ export ALICLOUD_ACCESS_KEY="<your AccessKey ID>"
# AccessKey secret
$ export ALICLOUD_SECRET_KEY="<your AccessKey secret>"
# If you use STS credentials, you must configure security_token.
$ export ALICLOUD_SECURITY_TOKEN="<your access token>"

After you set the environment variables, you do not need to declare credentials in the provider block. You can declare only the region.

provider "alicloud" {
  region = "cn-hangzhou"
}

You can also configure the region using the ALICLOUD_REGION environment variable. If the region is not explicitly declared and this environment variable is not set, the default value is cn-beijing.

Supported resources

Use Terraform to create and manage ECS resources

This section provides an example of how to create and manage ECS resources with Terraform.

1. Create a working directory. In the directory, create a configuration file named main.tf. The following code creates an ECS instance and its required VPC, security group, and vSwitch resources. Copy the code into the main.tf file.

   # Define a variable "region" with the default value "cn-beijing" to specify the Alibaba Cloud region.
   variable "region"{
     default = "cn-beijing"
   }
   
   # Configure the Alibaba Cloud provider to use the region defined in the "region" variable.
   provider "alicloud"{
     region = var.region
   }
   
   # Define a string variable "instance_type" with the default value "ecs.e-c1m1.large" to specify the ECS instance type.
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # Use a data source to query zone information. Filter the results by the specified instance type, resource creation type (such as VSwitch), and disk category.
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # Define a variable "vpc_cidr_block" with the default value "172.16.0.0/16" to specify the CIDR block for the VPC.
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # Define a variable "vsw_cidr_block" with the default value "172.16.0.0/24" to specify the CIDR block for the vSwitch.
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # Generate a random integer between 10000 and 99999 to ensure the uniqueness of some resource names.
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # Create a VPC named "vpc-test" and use the random integer to ensure the name is unique.
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # Create a security group, include the random integer in the name to ensure uniqueness, and associate it with the VPC created above.
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"  # The field name here was replaced.
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # Create a security group rule to allow all inbound TCP traffic and associate it with the previously created security group.
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"  # Modified here, nic_type is changed to 'intranet'.
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # Create a vSwitch, include the random integer in the name to ensure uniqueness, and associate it with the VPC and zone.
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # Create an ECS instance. Set multiple parameters such as the zone, security group, and instance type. Use the random integer to ensure the instance name is unique.
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # Modify the password based on your requirements.
   }

2. Run the following command to initialize the Terraform runtime environment.

   terraform init

   The following output indicates that Terraform is initialized successfully.

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. Run the following command to execute the code.

   terraform apply

   During the execution, enter yes when prompted and press Enter. Wait for the command to complete. If the following output appears, the code was executed successfully.

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. Verify the results

terraform show

References

• For more tutorials, see Terraform Tutorials.

• For more information about common Terraform commands, see Common Commands.

• If the `terraform init` command times out due to network latency and you cannot download the provider, see Configure an acceleration solution for Terraform Init.

• Terraform is available as a managed service in ROS. You can deploy Terraform templates in the ROS console. For more information, see Create a Terraform stack.