Quickly deploy BT-Panel

Click One-click Deployment. On the page that appears, configure the parameters as prompted, and then click Deploy Now.

The key parameters are described as follows:

• Region: Select the region where the ECS instance is located.

• Instance Source:

  If you have specific requirements for the billing method, disk, or network of the ECS instance, you must first purchase an ECS instance that runs Alibaba Cloud Linux 3. Then, select the existing instance. For more information, see Create an instance on the custom launch tab.

  Create a new instance

  ROS automatically creates a spot instance and deploys BT-Panel on the instance.

  • Instance Image: Alibaba Cloud Linux 3

  • Instance Type: Select an instance type based on your requirements. For more information, see Instance families.

  • Instance Password: Enter and confirm the password for the ECS instance.

  Select an existing instance

  ROS automatically deploys BT-Panel on the selected instance. The ECS instance must have internet access and run Alibaba Cloud Linux 3.2104.

  Note

  A public IP address is automatically assigned to the ECS instance. Alternatively, an elastic IP address (EIP) is associated with the ECS instance. For instructions on how to enable public bandwidth, see Enable public bandwidth.

ROS starts the automatic deployment. The deployment is successful when the progress reaches 100%.

Click the View Outputs tab to view and record the logon information for BT-Panel.

The output keywords are described as follows:

• EcsLoginAddress: The remote connection address of the ECS instance.

• Console@PRIVATE_URL: The private network logon address for BT-Panel.

• Console@PASSWORD: The logon password for BT-Panel.

• Console@USERNAME: The username for BT-Panel.

• Console@PublicURL: The public network logon address for BT-Panel.

  

On a Windows host with internet access, enter the public address of BT-Panel in a browser.

In this example, the public address of BT-Panel is https://47.105.XX.XX:8888/cad432be. Use the address that is displayed on the View Outputs tab. If you cannot access BT-Panel, see the following documents to troubleshoot the issue:

• BT-Panel official documentation FAQ

• Troubleshoot BT-Panel access issues

Enter the username and password that you recorded, and then log on to BT-Panel for Linux.

Select I have read and agree to the User Agreement and click Enter Panel.

After you bind your BT-Panel account, the Recommended installation suite dialog box appears. Install the software that you need.

For detailed usage instructions, see the BT-Panel official documentation.

Obtain the logon information for BT-Panel.

1. Remotely connect to the ECS instance. For more information, see Log on to a Linux instance using Workbench.

2. Run the following command to obtain the private and public addresses, username, and password for BT-Panel:

   bt default

   The command output is similar to the following:

   

In the inbound direction, add a rule to the security group of the ECS instance to allow access to port 8888 of BT-Panel. For more information, see Add a security group rule.

In this example, the BT-Panel port is 8888. Use the port number that you obtained in Step 1. For data security, this example allows access only to the required ports in addition to the default ports that are allowed when the server is created.

On a Windows host with internet access, enter the public address of BT-Panel, http://<ECS instance public IP>:8888/login, in a browser.

If you cannot access BT-Panel, see the following documents to troubleshoot the issue:

• BT-Panel official documentation FAQ

• Troubleshoot BT-Panel access issues

Enter the username and password that you recorded, and then log on to BT-Panel for Linux.

Select I have read and agree to the User Agreement and click Enter Panel.

After you bind your BT-Panel account, the Recommended installation suite dialog box appears. Install the software that you need.

For detailed usage instructions, see the BT-Panel official documentation.

Click Run Now to open Terraform Explorer. The following Terraform code is automatically loaded.

// Instance name
variable "name" {
  default = "terraform-example"
}

// Instance type
variable "instance_type" {
  default = "ecs.e-c1m2.xlarge"
}

// Instance logon password
variable "instance_password" {
  default = "Test@12345"
}

// Region
variable "region" {
  default = "cn-beijing"
}

provider "alicloud" {
  region = var.region
}

variable "create_instance" {
  default = true
}

// Instance ID
variable "instance_id" {
  default = ""
}

// Image ID
variable "image_id" {
  default = "debian_12_8_x64_20G_alibase_20241216.vhd"
}

// Create a VPC
resource "alicloud_vpc" "vpc" {
  count      = var.create_instance ? 1 : 0
  cidr_block = "192.168.0.0/16"
}

// Create a vSwitch
resource "alicloud_vswitch" "vswitch" {
  count        = var.create_instance ? 1 : 0
  vpc_id       = alicloud_vpc.vpc[0].id
  cidr_block   = "192.168.0.0/16"
  zone_id      = data.alicloud_zones.default.zones.0.id
  vswitch_name = var.name
}

// Create a security group
resource "alicloud_security_group" "group" {
  count               = var.create_instance ? 1 : 0
  security_group_name = var.name
  description         = "foo"
  vpc_id              = alicloud_vpc.vpc[0].id
}

// Create a security group rule (This is an example. Set the rule based on your security policy.)
resource "alicloud_security_group_rule" "allow_all_tcp" {
  count             = var.create_instance ? 1 : 0
  type              = "ingress"                           # Rule type: inbound
  ip_protocol       = "tcp"                               # Protocol type: TCP
  policy            = "accept"                            # Policy: accept
  port_range        = "22/22"                             # Port range: only port 22
  priority          = 1                                   # Priority: 1
  security_group_id = alicloud_security_group.group[0].id # Associate with the previously created security group
  cidr_ip           = "0.0.0.0/0"                         # Allow access from all IP addresses
}

resource "alicloud_security_group_rule" "allow_tcp_80" {
  count             = var.create_instance ? 1 : 0
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "80/80"
  priority          = 1
  security_group_id = alicloud_security_group.group[0].id
  cidr_ip           = "0.0.0.0/0"
}

resource "alicloud_security_group_rule" "allow_tcp_443" {
  count             = var.create_instance ? 1 : 0
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "443/443"
  priority          = 1
  security_group_id = alicloud_security_group.group[0].id
  cidr_ip           = "0.0.0.0/0"
}

resource "alicloud_security_group_rule" "allow_icmp_all" {
  count             = var.create_instance ? 1 : 0
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.group[0].id
  cidr_ip           = "0.0.0.0/0"
}

data "alicloud_zones" "default" {
  available_disk_category     = "cloud_essd"
  available_resource_creation = "VSwitch"
  available_instance_type     = var.instance_type
}

// Create an instance
resource "alicloud_instance" "instance" {
  count             = var.create_instance ? 1 : 0
  availability_zone = data.alicloud_zones.default.zones.0.id
  security_groups   = alicloud_security_group.group.*.id
  # series III
  instance_type              = var.instance_type
  system_disk_category       = "cloud_essd"
  system_disk_name           = var.name
  system_disk_description    = "test_foo_system_disk_description"
  image_id                   = var.image_id
  instance_name              = var.name
  vswitch_id                 = alicloud_vswitch.vswitch.0.id
  internet_max_bandwidth_out = 10
  password                   = var.instance_password
}

resource "alicloud_ecs_command" "install_content" {
  name            = "install_content"
  type            = "RunShellScript"
  command_content = base64encode(local.install_content)
  timeout         = 3600
  working_dir     = "/root"
  depends_on      = [alicloud_instance.instance]
}

resource "alicloud_ecs_invocation" "invocation_install" {
  instance_id = [local.instanceId]
  command_id  = alicloud_ecs_command.install_content.id
  timeouts {
    create = "15m"
  }
}

data "alicloud_instances" "default" {
  count = var.create_instance ? 0 : 1
  ids   = [var.instance_id]
}

locals {
  instanceId         = var.create_instance ? alicloud_instance.instance[0].id : var.instance_id
  instance_public_ip = var.create_instance ? element(alicloud_instance.instance.*.public_ip, 0) : lookup(data.alicloud_instances.default[0].instances.0, "public_ip")
  install_content    = <<SHELL
echo '#!/bin/bash
# Check the operating system version
if [ -f /etc/os-release ]; then
    source /etc/os-release || { echo "Cannot read the /etc/os-release file"; exit 1; }
    if [ -z "$${ID:-}" ] || [ -z "$${VERSION_ID:-}" ]; then
        echo "The /etc/os-release file format is not as expected or lacks necessary information"
        exit 1
    fi
    OS=$ID
    VER=$VERSION_ID
    echo "Operating system: $OS Version: $VER"
else
    echo "Cannot detect the operating system version. The /etc/os-release file does not exist"
    exit 1
fi
if [[ $OS == "alinux" ]]; then
url="https://download.bt.cn/install/install_lts.sh"
if [ -f /usr/bin/curl ]; then
    curl -sSO "$url"
else
    wget -O install_lts.sh "$url"
fi
yes | bash install_lts.sh ed8484bec

elif [[ $OS == "centos" ]]; then
url="https://download.bt.cn/install/install_lts.sh"
if [ -f /usr/bin/curl ]; then
    curl -sSO "$url"
else
    wget -O install_lts.sh "$url"
fi
yes | bash install_lts.sh ed8484bec
elif [[ $OS == "ubuntu" ]]; then
wget -O install.sh https://download.bt.cn/install/install_lts.sh && yes | sudo bash install.sh ed8484bec
elif [[ $OS == "debian" ]]; then
wget -O install.sh https://download.bt.cn/install/install_lts.sh && yes | bash install.sh ed8484bec
else
    echo "Unsupported operating system"
    exit 1
fi
' > install.sh
chmod +x install.sh
timeout 300s ./install.sh
bt default > credentials.txt
SHELL
}

output "credentials_info" {
  value = "To obtain the logon information for BT-Panel, log on to the ECS instance and view the credentials.txt file in the user's home directory"
}

output "ecs_login_address" {
  value = "ECS remote connection address: https://ecs-workbench.aliyun.com/?from=EcsConsole&instanceType=ecs&regionId=${var.region}&instanceId=${local.instanceId}"
}

Modify the parameters based on your requirements. By default, a VPC-connected instance and a pay-as-you-go ECS instance that runs Debian are created in the China (Beijing) region. For more information about instance billing, see Billing overview.

Click Start Debugging to preview the details of the resources to be created. If the resource information is correct, click Preview and Execute to start creating the resources. The deployment is complete when the task execution status is Successful.

Obtain the logon information for BT-Panel.

1. Remotely connect to the ECS instance. For more information, see Log on to a Linux instance using Workbench.

2. Run the following command to obtain the private and public addresses, username, and password for BT-Panel:

   bt default

   The command output is similar to the following:

   

In the inbound direction, add a rule to the security group of the ECS instance to allow access to port 8888 of BT-Panel. For more information, see Add a security group rule.

In this example, the BT-Panel port is 8888. Use the port number that you obtained in Step 1. For data security, this example allows access only to the required ports in addition to the default ports that are allowed when the server is created.

On a Windows host with internet access, enter the public address of BT-Panel, http://<ECS instance public IP>:8888/login, in a browser.

If you cannot access BT-Panel, see the following documents to troubleshoot the issue:

• BT-Panel official documentation FAQ

• Troubleshoot BT-Panel access issues

Enter the username and password that you recorded, and then log on to BT-Panel for Linux.

Select I have read and agree to the User Agreement and click Enter Panel.

After you bind your BT-Panel account, the Recommended installation suite dialog box appears. Install the software that you need.

For detailed usage instructions, see the BT-Panel official documentation.