VPCs and vSwitches

Console

API

Unlike in the console, calling the CreateVpc operation only creates an empty VPC. You must also call the CreateVSwitch operation to create a vSwitch.

• Call CreateVpc and then CreateVSwitch to create a VPC and a vSwitch.

• Call DeleteVSwitch and then DeleteVpc to delete a vSwitch and a VPC.

  1. Before you delete a vSwitch, make sure that it is not shared, not bound to a custom route table or network ACL, and that all cloud resources within it are released.

  2. Before you delete a VPC, make sure that all resources within it are released and that its connections to other network services, such as CEN, are removed.

Terraform

Resources: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Specify the region where you want to create the VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Use a data source to automatically retrieve a list of zones where you can create vSwitches.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query for zones where vSwitches can be created in the VPC.
  # available_instance_type = "ecs.g7.large"  # Query for zones where ECS instances can be created in the VPC.
  # available_resource_creation = "slb"  # Query for zones where SLB instances can be created in the VPC.
}

# Create a VPC. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # Specify the CIDR block. 
}

# Create a vSwitch. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # Specify the CIDR block. 
  vpc_id       = alicloud_vpc.example_vpc.id                       # Specify the ID of the VPC to which the vSwitch belongs. 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # Specify the zone to which the vSwitch belongs.
}

Console

API

Unlike in the console, an IPv6 Gateway is not automatically created when you enable IPv6 for a VPC and a vSwitch by calling an API. You must call CreateIpv6Gateway to create one yourself.

• When you create a VPC and a vSwitch, set the EnableIPv6 parameter in CreateVpc and CreateVSwitch to enable or disable IPv6. When you create a VPC, specify the Ipv6IpamPoolId and Ipv6CidrMask parameters to allocate an IPv6 CIDR block from a specified IPv6 IPAM pool to the VPC.

• For existing VPCs and vSwitches, modify the EnableIPv6 parameter of ModifyVpcAttribute and ModifyVSwitchAttribute to enable or disable IPv6. To assign an IPv6 CIDR block to a VPC from a specified IPv6 address pool, call AssociateVpcCidrBlock.

Terraform

Terraform currently supports only system-allocated IPv6 CIDR blocks. Allocation from an IPAM pool is not supported.

Resources: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Specify the region where you want to create the VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Use a data source to automatically retrieve a list of zones where you can create vSwitches.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query for zones where vSwitches can be created in the VPC.
  # available_instance_type = "ecs.g7.large"  # Query for zones where ECS instances can be created in the VPC.
  # available_resource_creation = "slb"  # Query for zones where SLB instances can be created in the VPC.
}

# Create a dual-stack VPC. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # Enable IPv6. Set the value to false to disable IPv6.
  ipv6_isp    = "BGP" # Specify the type of the IPv6 CIDR block.
}

# Create a dual-stack vSwitch. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # Enable IPv6. Set the value to false to disable IPv6.
  ipv6_cidr_block_mask = 1    # Specify the last 8 bits of the IPv6 CIDR block for the vSwitch. 
} 

Console

API

• Call CreateVSwitchCidrReservation to create a reserved CIDR block.

• Call GetVSwitchCidrReservationUsage to view used IP addresses.

• Call DeleteVSwitchCidrReservation to delete a reserved CIDR block.

Terraform

Resources: alicloud_vpc_vswitch_cidr_reservation

# Specify the region where the resource is located.
provider "alicloud" {
  region = "cn-hangzhou" # The region where the resource resides.
}

# Specify the ID of the vSwitch.
variable "vsw_id" {
  default = "vsw-xxx" # Replace with the actual ID of your vSwitch.
}

# Create a reserved CIDR block.
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # Specify the reserved CIDR block. 
}

Console

Before you create a VPC, ensure that you have created an IPAM instance and an IPAM pool in the IPAM console.

1. Go to the Create VPC page in the VPC console.

2. To allocate an IPv4 CIDR block, select Allocated by IPAM, choose an IPAM pool, and configure a mask. The system automatically allocates the first available CIDR block matching the specified mask length. You can also adjust the IPv4 CIDR block within the pre-provisioned range of the pool.

3. To enable IPv6, select Allocated by IPAM, choose an IPv6 IPAM pool, and then configure a mask or specify a CIDR block.

API

• If you have an existing IPAM pool:

  • Allocate an IPv4 CIDR block: You can call CreateVpc and pass the Ipv4IpamPoolId parameter to specify an IPAM pool and the Ipv4CidrMask parameter to specify a mask. A CIDR block is then allocated from the IPAM pool and used as the IPv4 CIDR block for the new VPC. Alternatively, you can pass the CidrBlock parameter to specify the CIDR block for the VPC instead of automatically allocating a CIDR block by specifying a mask.

  • Allocate an IPv6 CIDR block: If you pass both Ipv6IpamPoolId and Ipv6CidrMask, an IPv6 CIDR block is allocated to the VPC from the specified IPv6 IPAM pool.

• If you have not created an IPAM pool, call the following APIs in sequence to create one, and then create your VPC as described above.

  1. OpenVpcIpamService - Enable the IPAM feature

  2. CreateIpam - Create an IPAM instance

  3. CreateIpamPool - Create an IPAM pool

  4. AddIpamPoolCidr - Provision a CIDR block for an IPAM pool

Terraform

Terraform currently supports allocating only IPv4 CIDR blocks from an IPAM pool. Allocating IPv6 CIDR blocks is not supported.

Resources: vpc_ipam_ipam, alicloud_vpc_ipam_ipam_pool, alicloud_vpc_ipam_ipam_pool_cidr, alicloud_vpc

# Specify the region where you want to create the IPAM instance, IPAM pool, and VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Create an IPAM instance.
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # Specify the operating region of the IPAM instance.
}

# Create an IPAM pool.
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # Specify the scope of the IPAM pool.
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # Specify the region of the IPAM pool.
  ip_version     = "IPv4"                                     # Specify the IP version of the IPAM pool.
}

# Allocate a CIDR to the IPAM pool.
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # Specify the CIDR.
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool.
}

# Create a VPC.
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool.
  ipv4_cidr_mask    = 24                                                 # The IPv4 network mask.
}