通过Terraform创建云SSO用户

前提条件

• 建议使用RAM用户完成此教程的操作，并授予AliyunCloudSSOFullAccess权限，创建RAM用户请参见创建RAM用户，授权请参见为RAM用户授权。

• 准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。

  • Explorer：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。

  • Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。

  • 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

使用的资源

• alicloud_cloud_sso_directory：云SSO目录。

• alicloud_cloud_sso_user：云SSO用户。

创建云SSO用户

1. 创建一个文件夹作为Terraform工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下代码复制到main.tf中。

   variable "region" {
     default = "cn-shanghai"
   }
   
   provider "alicloud" {
     region = var.region
   }
   
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # 获取云SSO目录
   data "alicloud_cloud_sso_directories" "default" {}
   
   # 创建目录，一个账号只能创建一个目录
   resource "alicloud_cloud_sso_directory" "default" {
     directory_name = "sso-directory-${random_integer.default.result}"
     # 如果已有目录，则不新建目录；如果没有目录，则新建一个目录
     count          = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? 0 : 1
   }
   
   # directory_id 的值为全局唯一目录的id
   locals {
     directory_id = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? data.alicloud_cloud_sso_directories.default.ids[0] : concat(alicloud_cloud_sso_directory.default.*.id, [""])[0]
   }
   
   # 创建云SSO用户
   resource "alicloud_cloud_sso_user" "default" {
     user_name    = "sso-user-${random_integer.default.result}"
     directory_id = local.directory_id
   }

2. 执行如下命令，初始化Terraform运行环境。

   terraform init

   返回信息如下，则Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 执行如下命令，开始执行代码。

   terraform apply

   在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示代码执行成功。

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

4. 验证结果。

   执行terraform show命令

   您可以在工作目录中，使用以下命令查询Terraform已创建资源的详细信息：

   terraform show

   

   登录控制台查看

   登录云SSO控制台，查看已创建的用户。

   

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

variable "region" {
  default = "cn-shanghai"
}

provider "alicloud" {
  region = var.region
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

# 获取云SSO目录
data "alicloud_cloud_sso_directories" "default" {}

# 创建目录
resource "alicloud_cloud_sso_directory" "default" {
  directory_name = "sso-directory-${random_integer.default.result}"
  # 如果已有目录，则不新建目录；如果没有目录，则新建一个目录
  count          = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? 0 : 1
}

# directory_id 的值为全局唯一目录的id
locals {
  directory_id = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? data.alicloud_cloud_sso_directories.default.ids[0] : concat(alicloud_cloud_sso_directory.default.*.id, [""])[0]
}

# 创建云SSO用户
resource "alicloud_cloud_sso_user" "default" {
  user_name    = "sso-user-${random_integer.default.result}"
  directory_id = local.directory_id
}

如果您想体验更多完整示例，请前往更多完整示例中对应产品的文件夹查看。

相关文档

• Terrafrom介绍，请参见Terraform产品介绍。

• 当您遇到由于网络延迟等原因造成的terraform init超时，导致无法正常下载Provider等情况时，请参见Terraform Init 加速方案配置。