使用Terraform创建ACS集群_容器计算服务(ACS)-阿里云帮助中心

本文介绍如何使用Terraform创建ACS集群。

前提条件

已开通容器计算服务ACS。
由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式请参见创建RAM用户和创建AccessKey。

为运行Terraform命令的RAM用户绑定以下最小权限策略，以获取管理本示例所涉及资源的权限。更多信息，请参见为RAM用户授权。

该权限策略允许RAM用户进行ACS集群以及依赖云产品资源的创建、查看与删除操作。

{
  "Version": "1",
  "Statement": [
    {
      "Effect": "Allow",
      "Action": [
        "cs:CreateCluster",
        "cs:DescribeTaskInfo",
        "cs:DescribeClusterDetail",
        "cs:GetClusterCerts",
        "cs:CheckControlPlaneLogEnable",
        "cs:DeleteCluster",
        "cs:GetClusterAuditProject",
        "cs:ModifyCluster",
        "vpc:DescribeNatGateways"
      ],
      "Resource": "*"
    }
  ]
}

准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。
- Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。
  - RAM用户或角色使用Cloud Shell，需要主账号参考身份管理对RAM用户或角色授权权限。
- 在资源编排（ROS）中使用Terraform：资源编排服务（ROS）为Terraform提供了托管的能力，您可以创建Terraform类型的模板，定义阿里云、AWS或Azure资源，配置资源参数和资源间的依赖关系。
- 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。
重要
请确保版本不低于v0.12.28。如需检查现有版本，请运行terraform --version命令。

使用的资源

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行释放或退订。

alicloud_cs_managed_kubernetes：以创建ACK托管版集群为基础，创建ACS集群。

使用Terraform创建ACS集群

本示例将创建一个包含为该集群默认安装一系列组件，包括managed-csiprovisioner（存储组件）、ebs-token-controller（存储组件）、alibaba-log-controller（日志采集组件）、arms-prometheus（监控组件）等的ACS集群。

创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下参考代码复制到main.tf中，请根据需要修改。

provider "alicloud" {
  region      = var.region_id
}
variable "region_id" {
  type        = string
  default     = "cn-guangzhou"
}
variable "availability_zone" {
  type        = list(string)
  description = "The availability zones of vswitches."
  default     = ["cn-guangzhou-a", "cn-guangzhou-b"]
}
variable "k8s_name_prefix" {
  description = "The name prefix used to create ACS cluster."
  default     = "acs-example"
}
variable "acs_version" {
  type        = string
  description = "Desired Kubernetes version. "
  default     = "1.31.1-aliyun.1"      # 请按需修改
}
variable "service_cidr" {
  type        = string
  description = "The Kubernetes services CIDR. "
  default     = "10.13.0.0/16"      # 请按需修改
}

# 指定ACS集群安装的组件。包括alibaba-log-controller（日志采集组件）、arms-prometheus（监控组件）、managed-coredns、managed-metrics-server。
variable "cluster_addons" {   # 请按需修改
  type = list(object({
    name   = string
    config = string
  }))
  default = [
    {
      "name"   = "arms-prometheus",
      "config" = "",
    },
    {
      "name"   = "alibaba-log-controller",
      "config" = "",
    },
    {
      "name"   = "managed-coredns",
      "config" = "",
    },
    {
      "name"   = "managed-metrics-server",
      "config" = "",
    }
  ]
}
# 默认资源名称。
locals {
  k8s_name_acs     = substr(join("-", [var.k8s_name_prefix, "acs"]), 0, 63)
  log_project_name = "log-for-${local.k8s_name_acs}"
}

# 创建ACS集群。
resource "alicloud_cs_managed_kubernetes" "default" {
  name                         = local.k8s_name_acs   # Kubernetes集群名称。
  cluster_spec                 = "ack.pro.small"
  profile                      = "Acs"
  version                      = var.acs_version # 替换为您所需创建的集群版本。 
  zone_ids                     = var.availability_zone
  is_enterprise_security_group = true
  control_plane_log_ttl        = "30"    
  new_nat_gateway              = true   # 是否在创建Kubernetes集群时创建新的NAT网关。默认为true。                                                           
  control_plane_log_components = ["apiserver", "kcm", "scheduler", "ccm"] # 控制平面日志。
  deletion_protection          = true
  # 通过RRSA配置ServiceAccount。
  enable_rrsa                  = true
  timezone                     = "Asia/Shanghai"
  service_cidr                 = var.service_cidr  # 请按需修改
  slb_internet_enabled         = false  # 是否为API Server创建Internet负载均衡。默认为false。
  dynamic "addons" {  # 组件管理。
    for_each = var.cluster_addons
    content {
      name   = lookup(addons.value, "name", var.cluster_addons)
      config = lookup(addons.value, "config", var.cluster_addons)
    }
  }
}

说明

该配置文件仅为参考，请根据实际需要修改。

执行以下命令，初始化Terraform运行环境。

terraform init

返回如下信息，表示Terraform初始化成功。

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

创建执行计划，并预览变更。

terraform plan

执行以下命令，创建集群。

terraform apply

在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示ACS集群创建成功。

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

...
alicloud_cs_managed_kubernetes.default: Creation complete after 5m48s [id=ccb53e72ec6c447c990762800********]
...

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

验证结果

执行terraform show命令

您可以使用以下命令查询Terraform已创建资源的详细信息。

terraform show

登录ACS控制台

登录容器计算服务控制台，查看已创建的集群。

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行terraform destroy命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy