Terraform参考

Terraform基本功能

Terraform是IT基础架构自动化编排工具，可以用代码来管理维护IT资源。更多信息，请参见Terraform产品介绍。

• Terraform的命令行接口CLI（Command Line Interface）提供一种简单机制，用于将配置文件部署到阿里云或其他任意支持的云上，并对其进行版本控制。它编写了描述云资源拓扑的配置文件中的基础结构，例如虚拟机、存储账户和网络接口。

• Terraform通过Provider支持新的基础架构，让您在阿里云上能够轻松使用简单模板语言来定义、预览和部署云基础结构。

• Terraform可以创建、修改和删除多种阿里云产品的相关资源。

关于阿里云与Terraform集成的更多信息，请参见Alibaba Cloud Provider。

Terraform安装

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Terraform 身份认证

基于环境变量配置身份认证是将访问凭证保存在特定的环境变量中，当执行Terraform命令时，如果配置模板中没有显式声明访问凭证，那么将尝试从如下的环境变量中获取。具体环境变量的设置方式如下：

# Access Key Id
$ export ALICLOUD_ACCESS_KEY="<你的 Access Key ID>"
# Access Key Secret
$ export ALICLOUD_SECRET_KEY="<你的 Access Key Secret>"
# 如果是 STS 的访问凭证，此处需要配置 security_token
$ export ALICLOUD_SECURITY_TOKEN="<你的访问 Token>"

设置了环境变量之后，provider块可以不在配置模板中显式声明或者只声明地域信息：

provider "alicloud" {
  region = "cn-hangzhou"
}

当然，region也是支持通过环境变量 ALICLOUD_REGION进行配置的。如果 region 没有显式声明也没有配置环境变量，cn-beijing 将是其默认配置值。

支持的资源列表

使用Terraform创建并管理ECS

下文以创建ECS为例，介绍如何使用Terraform创建并管理ECS资源。

1. 创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件。以下代码将创建一个ECS实例，以及创建ECS实例所需的VPC、安全组与交换机资源。将以下代码复制到main.tf中。

   # 定义一个变量region，默认值为"cn-beijing"，用于指定阿里云区域
   variable "region"{
     default = "cn-beijing"
   }
   
   # 配置阿里云provider，使用变量region中定义的区域
   provider "alicloud"{
     region = var.region
   }
   
   # 定义一个字符串类型的变量instance_type，默认值为"ecs.e-c1m1.large"，用于指定ECS实例类型
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # 使用数据源查询可用区信息，通过指定的实例类型、资源创建类型（如VSwitch）以及磁盘种类来过滤结果
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # 定义一个变量vpc_cidr_block，默认值为"172.16.0.0/16"，用于指定VPC的CIDR块
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # 定义一个变量vsw_cidr_block，默认值为"172.16.0.0/24"，用于指定VSwitch的CIDR块
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # 生成一个介于10000到99999之间的随机整数，用于确保某些资源名称的唯一性
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # 创建名为vpc-test的VPC，并使用随机整数确保名称唯一性
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # 创建安全组，名称包含随机整数以保证唯一性，并关联至上述VPC
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"  # 替换了这里的字段名
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # 创建一条允许所有TCP流量进入的安全组规则，与之前创建的安全组关联
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"  # 修改了这里，将nic_type改为'intranet'
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # 创建VSwitch，名称中包含随机整数以确保唯一性，并与VPC、可用区关联
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # 创建ECS实例，设置多个参数如可用区、安全组、实例类型等，并使用随机整数保证实例名称的唯一性
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # 用户根据自己实际情况修改
   }

2. 执行如下命令，初始化Terraform运行环境。

   terraform init

   返回信息如下，则Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 执行如下命令，开始执行代码。

   terraform apply

   在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示代码执行成功。

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. 结果验证

terraform show

相关文档

• 更多实践教程，请参见Terraform的教程。

• 更多Terraform的常用命令，请参见Terraform常用命令。

• 当您遇到由于网络延迟等原因造成的 terraform init 超时，导致无法正常下载 Provider 等情况时，请参见Terraform Init 加速方案配置。

• ROS提供了Terraform托管服务，因此您可以直接在ROS控制台部署Terraform模板。详细操作，请参见创建Terraform类型资源栈。