错误处理

预定义异常

PolarDB PostgreSQL版（兼容Oracle）既支持原生PostgreSQL的所有预定义异常，如division_by_zero。同时也支持兼容Oracle语法中的常见预定义异常，如zero_divide。在SQL中既可以抛出这些异常，也可以捕获这些异常。

DECLARE
    result INT;
BEGIN
    result := 1 / 0;
END;

-- PostgreSQL 风格
BEGIN
    RAISE division_by_zero;
END;

-- Oracle 风格
BEGIN
    RAISE zero_divide;
END;

-- PostgreSQL 风格
DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN division_by_zero THEN
        DBMS_OUTPUT.PUT_LINE('division by zero');
END;

-- Oracle 风格
DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN zero_divide THEN
        DBMS_OUTPUT.PUT_LINE('zero divide');
END;

DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('division by zero');
END;

非预定义异常

在Oracle语法中，存在大量的错误码，其中只有少数错误码被定义为系统预定义异常。例如，错误码100对应于no_data_found异常，可以通过显式抛出RAISE no_data_found来引发该异常，并通过WHEN no_data_found进行异常捕获。

对于大量的非预定义异常，它们仅具备错误码而没有名称，如何抛出和捕获这些异常呢？为了解决这一问题，Oracle引入了异常变量。PolarDB PostgreSQL版（兼容Oracle）同样支持该特性：

1. 首先在DECLARE中声明异常变量，给定一个变量名，例如my_exception EXCEPTION;。

2. 通过PRAGMA EXCEPTION_INIT 语句为该变量绑定一个 SQLCODE，例如PRAGMA EXCEPTION_INIT(my_exception, -1476);。

   重要

   错误码存在范围限制，需为100（表示no_data_found异常）或在[-1000000, 0)范围内，且只有[-65535, 0)这个范围能够绑定到Oracle的合法SQLCODE，其他范围的错误码没有实际意义。

3. 在 EXCEPTION 段中可以用WHEN my_exception或WHEN OTHERS捕获该异常。

示例

DECLARE
    result INT;
    my_exception EXCEPTION;
    PRAGMA EXCEPTION_INIT(my_exception, -66666);
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN my_exception THEN
        DBMS_OUTPUT.PUT_LINE('zero divide');
END;

自定义异常（RAISE_APPLICATION_ERROR）

预定义异常和非预定义异常的错误码都属于Oracle预留的错误码范围，通常为[-65535, 0)范围的负数。除此以外，Oracle还提供了一个自定义异常错误码区间[-20000, -20999]，通过RAISE_APPLICATION_ERROR函数即可抛出自定义的错误码和错误消息。

示例

DECLARE
    salary NUMBER := 4000;
BEGIN
    -- 校验业务规则，不符合条件时触发错误
    IF salary < 5000 THEN
        RAISE_APPLICATION_ERROR(-20001, 'Salary is below the allowed minimum.');
    END IF;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('SQLCODE: ' || SQLCODE);
        DBMS_OUTPUT.PUT_LINE('Custom Error: ' || SQLERRM);
END;

错误码与错误信息

在EXCEPTION段中通过WHEN子句捕获到异常以后，如果希望获取异常的各项相关信息，可以通过如下方法：

• SQLSTATE：原生PostgreSQL的错误码，由五个字符的字符串组成，前两位表示类别（如语法错误、连接异常等），后三位表示具体错误子类。

• SQLCODE：兼容Oracle语法中的错误码，分为三类：

  • 100：表示no_data_found异常，查询语句无返回结果。

  • [-65535, 0)范围的负数：PolarDB PostgreSQL版（兼容Oracle）集群已兼容Oracle语法中的各类错误场景。

  • -99999：表示非法值，PolarDB PostgreSQL版（兼容Oracle）集群暂不支持当前场景。

• SQLERRM：错误信息，用于描述异常的详细情况。

DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('SQLCODE: ' || SQLCODE);
        DBMS_OUTPUT.PUT_LINE('SQLSTATE: ' || SQLSTATE);
        DBMS_OUTPUT.PUT_LINE('SQLERRM: ' || SQLERRM);
END;

SQLCODE: -1476
SQLSTATE: 22012
SQLERRM: division by zero