如何使用Terraform修改参数以及查询参数修改日志_云数据库 RDS(RDS)-阿里云帮助中心

本文介绍如何使用Terraform修改参数以及查询参数修改日志。

说明

本教程所含示例代码支持一键运行，您可以直接运行代码。一键运行

前提条件

已创建RDS PostgreSQL实例，详情请参见创建RDS PostgreSQL实例。
实例状态为运行中，您可以通过如下两种方式查看：
- 参见查询实例详情查看参数status，如果取值为Running则表示实例状态为运行中。
- 前往RDS管理控制台，切换到目标地域，找到指定实例后，查看实例状态。
由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式请参见创建RAM用户和创建AccessKey。

通过RAM授权，RAM用户可以有效地管理其云资源访问权限，适应多用户协同工作的需求，并且能够按需为用户分配最小权限，避免权限过大导致的安全漏洞。具体操作方式请参见为RAM用户授权。

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。
- 在Cloud Shell中使用Terraform：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。
- 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

使用的资源

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行释放或退订。

alicloud_vpc：创建专有网络VPC。
alicloud_vswitch：创建专有网络交换机。
alicloud_db_instance：创建RDS PostgreSQL实例。

修改参数

说明

部分参数修改后会立即重启实例，详情请参见控制台上可修改参数页面中的是否重启列。重启实例会造成连接中断，重启前请做好业务安排，谨慎操作。

本文以修改参数authentication_timeout的取值为120为例。

创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下代码复制到main.tf中。

创建前置资源。

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

# 创建VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 创建交换机
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 创建RDS PostgreSQL实例（默认版本为rds_postgres_1300_20240229）
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

在main.tf文件的resource "alicloud_db_instance" "instance" {}中增加parameters配置项，具体配置如下。

...
resource "alicloud_db_instance" "instance" {
...
parameters {
    name  = "authentication_timeout"
    value = "120"  
   }       
}

执行以下命令，初始化Terraform运行环境。

terraform init

返回如下信息，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

创建执行计划，并预览变更。
```
terraform plan
```

执行以下命令，创建资源。

terraform apply

在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

alicloud_db_instance.instance: Modifying... [id=pgm-****]
alicloud_db_instance.instance: Still modifying... [id=pgm-****, 10s elapsed]
...
alicloud_db_instance.instance: Still modifying... [id=pgm-****, 3m10s elapsed]
alicloud_db_instance.instance: Modifications complete after 3m10s [id=pgm-****]

Apply complete! Resources: 0 added, 1 changed, 0 destroyed.

验证结果。

执行terraform show命令

您可以使用以下命令查看参数修改情况。

terraform show

# alicloud_db_instance.instance:
resource "alicloud_db_instance" "instance" {
    acl                            = null
    auto_upgrade_minor_version     = "Auto"
    ca_type                        = null
    category                       = "HighAvailability"
    client_ca_cert                 = (sensitive value)
    client_ca_enabled              = 0
    client_cert_revocation_list    = null
    client_crl_enabled             = 0
    connection_string              = "pgm-f8z03v853neh87k8.pg.rds.aliyuncs.com"
    connection_string_prefix       = "pgm-f8z03v853neh87k8"
    create_time                    = "2024-10-31T02:29:36Z"
    db_instance_ip_array_attribute = null
    db_instance_ip_array_name      = null
    db_instance_storage_type       = "cloud_essd"
    db_instance_type               = "Primary"
    db_param_group_id              = null
    db_time_zone                   = "Asia/Shanghai"
    deletion_protection            = false
    engine                         = "PostgreSQL"
    engine_version                 = "13.0"
    force_restart                  = false
    ha_config                      = "Auto"
    id                             = "pgm-f8z03v853neh87k8"
    instance_charge_type           = "Postpaid"
    instance_name                  = null
    instance_storage               = 30
    instance_type                  = "pg.n2.2c.2m"
    maintain_time                  = "18:00Z-22:00Z"
    manual_ha_time                 = null
    monitoring_period              = 300
    node_id                        = "32990438"
    period                         = 0
    port                           = "5432"
    private_ip_address             = "172.16.206.226"
    replication_acl                = null
    resource_group_id              = "rg-acfmykd63gtpfpa"
    security_group_ids             = []
    security_ip_mode               = "normal"
    security_ip_type               = null
    security_ips                   = [
        "127.0.0.1",
    ]
    server_cert                    = (sensitive value)
    server_key                     = null
    sql_collector_config_value     = 30
    sql_collector_status           = "Disabled"
    ssl_action                     = "Close"
    ssl_connection_string          = null
    ssl_status                     = null
    status                         = "Running"
    storage_auto_scale             = null
    storage_threshold              = 0
    storage_upper_bound            = 0
    target_minor_version           = "rds_postgres_1300_20240830"
    tcp_connection_type            = "LONG"
    tde_status                     = "Disabled"
    vpc_id                         = "vpc-f8zvtuuan0tjyas7muymk"
    vswitch_id                     = "vsw-f8zjvdbtv24927fmvrydl"
    whitelist_network_type         = null
    zone_id                        = "cn-heyuan-a"

    parameters {
        name  = "authentication_timeout"
        value = "120"
    }
}

登录RDS管理控制台

登录RDS管理控制台查看参数修改情况。修改参数

查询参数修改日志

在上述main.tf文件中增加data "alicloud_rds_modify_parameter_logs" "querylogs"配置项，具体配置如下：

...
resource "time_static" "example" {}

data "alicloud_rds_modify_parameter_logs" "querylogs" {
  db_instance_id = alicloud_db_instance.instance.id
  start_time     = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "-12h"))
  end_time       = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "12h"))
}

执行以下命令。

terraform apply

在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

alicloud_db_instance.instance: Refreshing state... [id=pgm-****]
data.alicloud_rds_modify_parameter_logs.querylogs: Reading...
alicloud_db_backup_policy.instance: Refreshing state... [id=pgm-****]
data.alicloud_rds_modify_parameter_logs.querylogs: Read complete after 0s [id=6335****]

No changes. Your infrastructure matches the configuration.

Terraform has compared your real infrastructure against your configuration and found no differences, so no changes are needed.

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

验证结果。

执行terraform show命令

您可以使用以下命令查看参数修改日志。

terraform show

# data.alicloud_rds_modify_parameter_logs.querylogs:
data "alicloud_rds_modify_parameter_logs" "querylogs" {
    db_instance_id = "pgm-f8z03v853neh87k8"
    end_time       = "2024-10-31T23:59Z"
    id             = "6722ee94"
    logs           = [
        {
            modify_time         = "1730342339000"
            new_parameter_value = "120"
            old_parameter_value = "60"
            parameter_name      = "authentication_timeout"
            status              = "Applied"
        },
    ]
    start_time     = "2024-10-31T00:00Z"
}

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

variable "region" {
  default = "cn-heyuan"
}

variable "zone_id" {
  default = "cn-heyuan-a"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# 创建VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 创建交换机
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 创建RDS PostgreSQL实例
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
  # 修改参数,修改完参数后需再次运行terraform apply
  parameters {
    name  = "authentication_timeout"
    value = "120"
  }
}
# 获取当前时间
resource "time_static" "example" {}

# 查询参数修改日志
data "alicloud_rds_modify_parameter_logs" "querylogs" {
  db_instance_id = alicloud_db_instance.instance.id
  start_time     = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "-12h"))
  end_time       = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "12h"))
}

如果您想体验更多完整示例，请前往更多完整示例中对应产品的文件夹查看。

通过 Terraform 管理RDS PostgreSQL实例参数

前提条件

使用的资源

修改参数

执行terraform show命令

登录RDS管理控制台

查询参数修改日志

执行terraform show命令

清理资源

完整示例

示例代码

相关文档