AI 助理
备案控制台登录注册
官方文档
输入文档关键字查找
首页Terraform实践教程RDS（云数据库）通过 Terraform 恢复 RDS PostgreSQL 实例

通过 Terraform 恢复 RDS PostgreSQL 实例

更新时间：2024-12-19 02:50:57
我的收藏

本文介绍如何使用Terraform恢复实例。

说明

本教程所含示例代码支持一键运行，您可以直接运行代码。一键运行

前提条件

  • 已创建RDS PostgreSQL实例，详情请参见创建RDS PostgreSQL实例。

  • 实例状态为运行中，您可以通过如下两种方式查看：

    • 参见查询实例详情查看参数status，如果取值为Runing则表示实例状态为运行中。

    • 前往RDS管理控制台，切换到目标地域，找到指定实例后，查看实例状态。

  • 由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式请参见创建RAM用户和创建AccessKey。

  • 通过RAM授权，RAM用户可以有效地管理其云资源访问权限，适应多用户协同工作的需求，并且能够按需为用户分配最小权限，避免权限过大导致的安全漏洞。具体操作方式请参见为RAM用户授权。

    {
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

  • 准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。

    • 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。

    • Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。

    • 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

使用的资源

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行释放或退订。

按时间点恢复实例

  1. 创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下代码复制到main.tf中。

    • 创建前置资源。

      variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

# 创建VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 创建交换机
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 创建RDS PostgreSQL实例
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

# 创建备份
resource "alicloud_rds_backup" "instance" {
  db_instance_id    = alicloud_db_instance.instance.id
  remove_from_state = true
}

# 查询备份
data "alicloud_rds_backups" "example" {
  db_instance_id = alicloud_db_instance.instance.id
  depends_on     = [alicloud_rds_backup.instance]
}

    • 在main.tf文件中增加resource "alicloud_rds_clone_db_instance" "clone_time" {}配置项，具体配置如下。

      # 按时间点恢复实例
resource "alicloud_rds_clone_db_instance" "clone_time" {
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_description  = "terraform-test-clone"
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 模拟获取查询结果中backup_end_time的参数取值。
  restore_time             = data.alicloud_rds_backups.example.backups.0.backup_end_time
  db_instance_storage      = "50"
}
    说明

    restore_time参数配置的取值获取方法：

    1. 在terraform.tf文件中增加data "alicloud_rds_backups" "example" { db_instance_id = alicloud_db_instance.instance.id}配置项查询备份。

    2. 使用terraform apply执行查询。

    3. 使用terraform show查询备份信息，获取查询结果中backup_end_time的参数取值。

    具体操作，请参见通过 Terraform 管理 RDS PostgreSQL 备份。

  2. 执行以下命令，初始化Terraform运行环境。

    terraform init

    返回如下信息，表示Terraform初始化成功。

    Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

  3. 创建执行计划，并预览变更。

    terraform plan

  4. 执行以下命令，创建资源。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

    alicloud_rds_clone_db_instance.example: Creating...
alicloud_rds_clone_db_instance.example: Still creating... [10s elapsed]
...
alicloud_rds_clone_db_instance.example: Still creating... [24m11s elapsed]
alicloud_rds_clone_db_instance.example: Creation complete after 24m34s [id=pgm-****]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

  5. 验证结果。

    执行terraform show命令
    登录RDS管理控制台

    您可以使用以下命令查看实例恢复情况。

    terraform show
    ...
# alicloud_rds_clone_db_instance.example:
resource "alicloud_rds_clone_db_instance" "example" {
    category                 = "HighAvailability"
    connection_string        = "pgm-****.pg.rds.aliyuncs.com"
    db_instance_class        = "pg.n2.2c.2m"
    db_instance_storage      = 50
    db_instance_storage_type = "cloud_essd"
    deletion_protection      = false
    engine                   = "PostgreSQL"
    engine_version           = "13.0"
    ha_mode                  = "RPO"
    id                       = "pgm-****"
    instance_network_type    = "VPC"
    maintain_time            = "18:00Z-22:00Z"
    payment_type             = "PayAsYouGo"
    port                     = "5432"
    private_ip_address       = "192.168.XX.XX"
    restore_time             = "2022-09-29T04:32:59Z"
    security_ips             = [
        "0.0.0.0/0",
    ]
    source_db_instance_id    = "pgm-****"
    sync_mode                = "Async"
    tcp_connection_type      = "LONG"
    vswitch_id               = "vsw-****"
    zone_id                  = "cn-hangzhou-j"
}

    登录RDS管理控制台查看实例恢复情况。恢复实例

按备份集恢复实例

  1. 在main.tf文件中增加resource "alicloud_rds_clone_db_instance" "clone_id" {}配置项，具体配置如下。

    ...
resource "alicloud_rds_clone_db_instance" "clone_id" {
  db_instance_description  = "terraform-test-clone-1"
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 模拟获取查询结果中backup_id的参数取值。
  backup_id                = data.alicloud_rds_backups.example.backups.0.backup_id
  db_instance_storage      = "50"
}
    说明

    backup_id参数配置的取值获取方法：

    • 在terraform.tf文件中增加data "alicloud_rds_backups" "querybackups" {db_instance_id = alicloud_db_instance.instance.id}配置项查询备份。

    • 使用terraform apply执行查询。

    • 使用terraform show查询备份信息，获取查询结果中backup_id的参数取值。

    具体操作，请参见通过 Terraform 管理 RDS PostgreSQL 备份。

  2. 执行以下命令。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

    alicloud_rds_clone_db_instance.example: Creating...
alicloud_rds_clone_db_instance.example: Still creating... [10s elapsed]
...
alicloud_rds_clone_db_instance.example: Still creating... [19m31s elapsed]
alicloud_rds_clone_db_instance.example: Creation complete after 19m39s [id=pgm-bp1sox718o31j940]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

  3. 验证结果。

    执行terraform show命令
    登录RDS管理控制台

    您可以使用以下命令查看实例恢复情况。

    terraform show
    ...
# alicloud_rds_clone_db_instance.example:
resource "alicloud_rds_clone_db_instance" "example" {
    backup_id                = "1499356764"
    category                 = "HighAvailability"
    connection_string        = "pgm-****.pg.rds.aliyuncs.com"
    db_instance_class        = "pg.n2.2c.2m"
    db_instance_storage      = 50
    db_instance_storage_type = "cloud_essd"
    deletion_protection      = false
    engine                   = "PostgreSQL"
    engine_version           = "13.0"
    ha_mode                  = "RPO"
    id                       = "pgm-****"
    instance_network_type    = "VPC"
    maintain_time            = "18:00Z-22:00Z"
    payment_type             = "PayAsYouGo"
    port                     = "5432"
    private_ip_address       = "192.168.XX.XX"
    security_ips             = [
        "0.0.0.0/0",
    ]
    source_db_instance_id    = "pgm-****"
    sync_mode                = "Async"
    tcp_connection_type      = "LONG"
    vswitch_id               = "vsw-****"
    zone_id                  = "cn-hangzhou-j"
}

    登录RDS管理控制台查看实例恢复情况。按备份集恢复

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

 
variable "region" {
  default = "cn-heyuan"
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# 创建VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 创建交换机
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 创建RDS PostgreSQL实例
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

# 创建备份
resource "alicloud_rds_backup" "instance" {
  db_instance_id    = alicloud_db_instance.instance.id
  remove_from_state = true
}

# 查询备份
data "alicloud_rds_backups" "example" {
  db_instance_id = alicloud_db_instance.instance.id
  depends_on     = [alicloud_rds_backup.instance]
}

# 按时间点恢复实例
resource "alicloud_rds_clone_db_instance" "clone_time" {
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_description  = "terraform-test-clone"
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 模拟获取查询结果中backup_end_time的参数取值。
  restore_time             = data.alicloud_rds_backups.example.backups.0.backup_end_time
  db_instance_storage      = "50"
}

# 按备份集恢复实例
resource "alicloud_rds_clone_db_instance" "clone_id" {
  db_instance_description  = "terraform-test-clone-1"
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 模拟获取查询结果中backup_id的参数取值。
  backup_id                = data.alicloud_rds_backups.example.backups.0.backup_id
  db_instance_storage      = "50"
}

如果您想体验更多完整示例，请前往更多完整示例中对应产品的文件夹查看。

相关文档

  • terraform介绍，请参见Terraform产品介绍。

  • 当您遇到由于网络延迟等原因造成的terraform init超时，导致无法正常下载Provider等情况时，请参见Terraform Init 加速方案配置。

  • 资源编排服务为Terraform提供了托管的能力，您可以创建Terraform类型的模板，定义RDS资源，配置资源参数和资源间的依赖关系。更多信息，请参见创建Terraform类型模板。

上一篇：创建一个云数据库实例下一篇：通过 Terraform 开启和关闭RDS PostgreSQL的SQL审计
  • 本页导读 （1）
  • 前提条件
  • 使用的资源
  • 按时间点恢复实例
  • 按备份集恢复实例
  • 清理资源
  • 完整示例
  • 示例代码
  • 相关文档
AI助理

点击开启售前

在线咨询服务

你好，我是AI助理

可以解答问题、推荐解决方案等