AI 助理
备案控制台登录注册
文档
输入文档关键字查找
首页Terraform实践教程MongoDB（云数据库MongoDB版）Terraform集成示例

Terraform集成示例

更新时间：2025-03-12 07:48:21
我的收藏

本文为您演示如何通过Terraform创建云数据库 MongoDB 版实例。

说明

当前示例代码支持一键运行，您可以直接运行代码。

如果您还不了解Terraform，请参见Terraform产品介绍。关于支持的MongoDB资源类型，请参见集成概览或直接查找Terraform文档。

资源架构

image.png

在指定地域创建一个VPC网络和一台交换机，然后创建一个MongoDB副本集实例。

前提条件

  • 由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式，请参见创建RAM用户和创建AccessKey。

  • 为RAM用户授予AliyunMongoDBFullAccess（管理云数据库服务（MongoDB））和AliyunVPCFullAccess（管理专有网络（VPC））权限。授权示例如下，如何授权，请参见为RAM用户授权。

    {
    "Version": "1",
    "Statement": [
        {
            "Action": "dds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": [
                "vpc:DescribeVpcs",
                "vpc:DescribeVSwitches",
                "vpc:CreateVpc",
                "vpc:DeleteVpc",
                "vpc:ModifyVpcAttribute",
                "vpc:CreateVSwitch",
                "vpc:DeleteVSwitch",
                "vpc:ModifyVSwitchAttribute"
            ],
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:dds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:dds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": "mongodb.aliyuncs.com"
                }
            }
        }
    ]
}

  • 准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。

    • 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。

    • Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。

    • 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

重要

请确保Terraform版本不低于v0.12.28。如需检查现有版本，请运行terraform --version命令。

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行退订。

使用的资源

使用Terraform创建云数据库 MongoDB 版实例

  1. 创建一个工作目录，并且在工作目录中创建以下名为main.tf的配置文件。main.tf是Terraform主文件，定义了将要部署的资源。

    单节点
    副本集
    分片集群
    variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
# 声明变量名: name
variable "name" {
  default = "terraform-example-1125"
}
variable "engine_version" {
  default = "7.0"
}
variable "db_instance_class" {
  default = "mdb.shard.2x.xlarge.d"
}
# 查询可用区信息: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
}
# 声明本地值, zone_id 取 alicloud_mongodb_zones 中的最后一个可用区
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}
# 创建 alicloud_vpc 资源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地区创建 alicloud_vpc 资源下的 alicloud_vswitch 资源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch信息创建单节点资源
resource "alicloud_mongodb_instance" "singleNode" {
  # （必填）数据库版本。
  engine_version      = var.engine_version
  # （必填）实例规格。
  db_instance_class   = var.db_instance_class
  # （必填，整型）用户定义的数据库实例存储空间。单位：GB。
  db_instance_storage = 20
  # 实例的网络类型
  network_type        = "VPC"
  # （可选，需强制新建）在一个 VPC 中启动数据库实例的虚拟交换机 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # （可选，需强制新建）启动数据库实例的可用区。
  zone_id             = local.zone_id
  # 实例名称  
  name                = var.name
  # （可选，自 v1.199.0 起可用）实例的存储类型。
  # storage_type        = "cloud_auto"
  # （可选）要分配给资源的标签映射。
  # tags = {
  #   Created = "TF"
  #   For     = "example"
  #   }
  # （可选，列表）允许访问实例所有数据库的 IP 地址列表。
  # security_ip_list    = [
        # "10.168.1.12",
        # "100.69.7.112"
  #   ]
}

    关于alicloud_mongodb_instance资源类型的配置信息，请参见资源详情。

    variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
# 声明变量名: name
variable "name" {
  default = "terraform-example-1125"
}
variable "engine_version" {
  default = "7.0"
}
variable "db_instance_class" {
  default = "mdb.shard.2x.xlarge.d"
}

# 查询可用区信息: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
}

# 声明本地值, zone_id 取 alicloud_mongodb_zones 中的最后一个可用区
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}

# 创建 alicloud_vpc 资源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地区创建 alicloud_vpc 资源下的 alicloud_vswitch 资源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch信息创建副本集资源
resource "alicloud_mongodb_instance" "default" {
  engine_version      = var.engine_version
  db_instance_class   = var.db_instance_class
  db_instance_storage = 20
  network_type        = "VPC"
  vswitch_id          = alicloud_vswitch.default.id
  vpc_id              = alicloud_vpc.vpc1.id
  security_ip_list    = ["10.168.1.12", "100.69.7.112"]
  name                = var.name
  tags = {
    Created = "TF"
    For     = "example"
  }
}

    关于alicloud_mongodb_instance资源类型的配置信息，请参见资源详情。

    variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}

# 声明变量名: name
variable "name" {
  default = "terraform-example-1125"
}

# 查询可用区信息: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
  
}

# 声明本地值, zone_id 取 alicloud_mongodb_zones 中的最后一个可用区
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}

# 创建 alicloud_vpc 资源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地区创建 alicloud_vpc 资源下的 alicloud_vswitch 资源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch信息创建分片集群资源
resource "alicloud_mongodb_sharding_instance" "default" {
  # (必填) 数据库版本
  engine_version      = "7.0"
  # (可选，ForceNew) 启动 DB 实例的虚拟交换机 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # 实例的网络类型
  network_type        = "VPC"
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # 实例名称
  name                = var.name
  # 可选地区
  zone_id = local.zone_id
  # 实例的 Mongo 节点。可购买的 mongo 节点数范围为 [2, 32]，见下方的 mongo_list。
  mongo_list {
    # (必填) mongo 节点的实例类型
    node_class = "mdb.shard.2x.xlarge.d"
  }
  mongo_list {
    node_class = "mdb.shard.2x.xlarge.d"
  }
  # (必填，集合) 实例的分片节点。可购买的 shard 节点数范围为 [2, 32]，见下方的 shard_list。
  shard_list {
    # (必填) 分片节点的实例类型
    node_class   = "mdb.shard.2x.xlarge.d"
    #  (必填，Int) 分片节点的存储空间。
    node_storage = "20"
  }
  shard_list {
    node_class        = "mdb.shard.2x.xlarge.d"
    node_storage      = "20"
    # 分片节点中只读节点的数量。默认值：0。有有效值：0 到 5。
    readonly_replicas = "1"
  }
  config_server_list {
    # 配置服务器节点的实例类型。有效值：mdb.shard.2x.xlarge.d，dds.cs.mid。
    node_class ="mdb.shard.2x.xlarge.d"
    # 配置服务器节点的存储空间。
    node_storage = "20"
  }
  # 
  tags = {
    Created = "TF"
    For     = "Example"
  }
}

    关于alicloud_mongodb_sharding_instance资源类型的配置信息，请参见资源详情。

  2. 执行以下命令，初始化Terraform运行环境。

    terraform init

    返回如下信息，表示Terraform初始化成功。

    Initializing the backend...

Initializing provider plugins...
- Finding latest version of hashicorp/alicloud...
- Installing hashicorp/alicloud v1.234.0...
- Installed hashicorp/alicloud v1.234.0 (signed by HashiCorp)

Terraform has created a lock file .terraform.lock.hcl to record the provider
selections it made above. Include this file in your version control repository
so that Terraform can guarantee to make the same selections by default when
you run "terraform init" in the future.

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

  3. 创建执行计划，并预览变更。

    terraform plan

  4. 执行以下命令，创建云数据库 MongoDB 版实例。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示创建云数据库 MongoDB 版实例成功。

    Plan: 3 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

alicloud_vpc.vpc1: Creating...
alicloud_vpc.vpc1: Creation complete after 6s [id=vpc-f8zov2h1snsl2bm9qz***]
alicloud_vswitch.default: Creating...
alicloud_vswitch.default: Creation complete after 3s [id=vsw-f8zswqowidqw16ypc2***]
alicloud_mongodb_instance.singleNode: Creating...
alicloud_mongodb_instance.singleNode: Still creating... [10s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [20s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [30s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [40s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [50s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [1m0s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [1m10s elapsed]

...

alicloud_mongodb_instance.singleNode: Still creating... [14m11s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [14m21s elapsed]
alicloud_mongodb_instance.singleNode: Creation complete after 14m29s [id=dds-f8z3a787aea1c***]

Apply complete! Resources: 3 added, 0 changed, 0 destroyed.

  5. 验证结果 。

    执行terraform show命令
    登录云数据库Mongo DB控制台

    您可以使用以下命令查询Terraform已创建的资源详细信息：

    terraform show

    image

    创建完成后，您可以通过OpenAPI、SDK或者登录云数据库Mongo DB控制台，检查操作是否正确完成。image

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

 
variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
# 声明变量名: name
variable "name" {
  default = "terraform-example-1125"
}
variable "engine_version" {
  default = "7.0"
}
variable "db_instance_class" {
  default = "mdb.shard.2x.xlarge.d"
}
# 查询可用区信息: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
}
# 声明本地值, zone_id 取 alicloud_mongodb_zones 中的最后一个可用区
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}
# 创建 alicloud_vpc 资源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地区创建 alicloud_vpc 资源下的 alicloud_vswitch 资源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch信息创建单节点资源
resource "alicloud_mongodb_instance" "singleNode" {
  # （必填）数据库版本。
  engine_version      = var.engine_version
  # （必填）实例规格。
  db_instance_class   = var.db_instance_class
  # （必填，整型）用户定义的数据库实例存储空间。单位：GB。
  db_instance_storage = 20
  # 实例的网络类型
  network_type        = "VPC"
  # （可选，需强制新建）在一个 VPC 中启动数据库实例的虚拟交换机 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # （可选，需强制新建）启动数据库实例的可用区。
  zone_id             = local.zone_id
  # 实例名称  
  name                = var.name
  # （可选）要分配给资源的标签映射。
  tags = {
    Created = "TF"
    For     = "example"
    }
  # （可选，列表）允许访问实例所有数据库的 IP 地址列表。
  security_ip_list    = [
         "10.168.1.12",
         "100.69.7.112"
     ]
  # （可选，自 v1.199.0 起可用）实例的存储类型。
  # storage_type        = "cloud_auto"   
}
# 使用上述vpc、vswitch信息创建分片集群资源
resource "alicloud_mongodb_sharding_instance" "default" {
  # (必填) 数据库版本
  engine_version      = "7.0"
  # (可选，ForceNew) 启动 DB 实例的虚拟交换机 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # 实例的网络类型
  network_type        = "VPC"
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # 实例名称
  name                = var.name
  # 可选地区
  zone_id = local.zone_id
  # 实例的 Mongo 节点。可购买的 mongo 节点数范围为 [2, 32]，见下方的 mongo_list。
  mongo_list {
    # (必填) mongo 节点的实例类型
    node_class = "mdb.shard.2x.xlarge.d"
  }
  mongo_list {
    node_class = "mdb.shard.2x.xlarge.d"
  }
  # (必填，集合) 实例的分片节点。可购买的 shard 节点数范围为 [2, 32]，见下方的 shard_list。
  shard_list {
    # (必填) 分片节点的实例类型
    node_class   = "mdb.shard.2x.xlarge.d"
    #  (必填，Int) 分片节点的存储空间。
    node_storage = "20"
  }
  shard_list {
    node_class        = "mdb.shard.2x.xlarge.d"
    node_storage      = "20"
    # 分片节点中只读节点的数量。默认值：0。有有效值：0 到 5。
    readonly_replicas = "1"
  }
  config_server_list {
    # 配置服务器节点的实例类型。有效值：mdb.shard.2x.xlarge.d，dds.cs.mid。
    node_class ="mdb.shard.2x.xlarge.d"
    # 配置服务器节点的存储空间。
    node_storage = "20"
  }
  # 
  tags = {
    Created = "TF"
    For     = "Example"
  }
}

如果您想体验更多完整示例，请前往更多完整示例中对应产品的文件夹查看。

上一篇：MongoDB（云数据库MongoDB版）下一篇：OOS（系统运维管理）
  • 本页导读 （1）
  • 资源架构
  • 前提条件
  • 使用的资源
  • 使用Terraform创建云数据库 MongoDB 版实例
  • 清理资源
  • 完整示例
  • 示例代码
  • 相关文档
AI助理

点击开启售前

在线咨询服务

你好，我是AI助理

可以解答问题、推荐解决方案等