AI 助理
备案控制台
文档
输入文档关键字查找
首页Terraform实践教程HBase（云数据库）通过Terraform创建HBase集群

通过Terraform创建HBase集群

更新时间：2025-03-12 07:59:39
我的收藏

本文为您介绍RAM用户如何使用Terraform调用云数据库 HBase 版（ApsaraDB for Hbase）的OpenAPI创建HBase集群。

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

前提条件

  • 由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式，请参见创建RAM用户和创建AccessKey。

  • 为RAM用户授予AliyunHBaseFullAccess（管理云数据库服务（HBase））和AliyunVPCFullAccess（管理专有网络（VPC））权限。授权示例如下，如何授权，请参见为RAM用户授权。

    {
    "Version": "1",
    "Statement": [
        {
            "Action": [
                "vpc:CreateVpc",
                "vpc:DescribeVpc",
                "vpc:ModifyVpcAttribute",
                "vpc:DeleteVpc",
                "vpc:CreateVSwitch",
                "vpc:DescribeVSwitch",
                "vpc:ModifyVSwitchAttribute",
                "vpc:DeleteVSwitch"
            ],
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "hbase:*",
            "Resource": "*",
            "Effect": "Allow"
        }
    ]
}

  • 准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。

    • 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。

    • Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。

    • 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

重要

请确保Terraform版本不低于v0.12.28。如需检查现有版本，请运行terraform --version命令。

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行退订。

使用的资源

使用Terraform创建HBase集群

  1. 创建一个工作目录，并且在工作目录中创建以下名为main.tf的配置文件。main.tf是Terraform主文件，定义了将要部署的资源。

    variable "region" {
  default = "cn-qingdao"
}
provider "alicloud" {
  region = var.region
}
data "alicloud_hbase_zones" "default" {}
variable "instance_type" {
  default = "hbase.sn2.large"
}
variable "name" {
  default = "hbasetest"
}
# 创建 alicloud_vpc 资源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}
# 在 local.zone_id 地区创建 alicloud_vpc 资源下的 alicloud_vswitch 资源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = data.alicloud_hbase_zones.default.zones[0].id
}
resource "alicloud_hbase_instance" "default" {
  # (必填) HBase 实例名称，长度必须为 2-128 个字符，只允许使用中文字符、英文字母、数字、句点 (.)、下划线 (_) 或短横线 (-)。
  name        = var.name
  #  (可选，ForceNew) 启动 HBase 实例的区域。
  zone_id                = data.alicloud_hbase_zones.default.zones[0].id
  # (可选，ForceNew) 
  vswitch_id             = alicloud_vswitch.default.id
  #  (可选，ForceNew，从 v1.185.0 起可用) VPC 的 ID。
  vpc_id                 = alicloud_vpc.vpc1.id
  #  (可选，ForceNew) 有效值为 "hbase/hbaseue/bds"。自 v1.73.0 之后支持的类型包括 hbaseue 和 bds。单个 HBase 实例需要设置 engine=hbase，core_instance_quantity=1。
  engine                 = "hbaseue"
  # (必填，ForceNew) HBase 主版本，hbase:1.1/2.0, hbaseue:2.0, bds:1.0，当前暂不支持其他引擎。
  engine_version         = "2.0"
  # (必填) 实例规格
  master_instance_type   = var.instance_type
  # (必填) 实例规格
  core_instance_type     = var.instance_type
  # (可选) 默认值为 2，范围为 [1-200]。若 core_instance_quantity > 1，则为集群实例；若 core_instance_quantity = 1，则为单个实例。
  core_instance_quantity = "2"
  #  (可选，ForceNew) 有效值为 cloud_ssd, cloud_essd_pl1, cloud_efficiency, local_hdd_pro, local_ssd_pro，``，local_disk 大小是固定的。当 engine=bds 时，无需设置磁盘类型（或空字符串）。
  core_disk_type         = "cloud_ssd"
  # (可选) 用户定义的 HBase 实例每个核心节点的存储，仅在 engine=hbase/hbaseue 时有效。Bds 引擎无需设置 core_disk_size，单位：GB。值范围：
  # 自定义存储空间，值范围：[20, 64000]。
  # 集群 [400, 64000]，步长：40-GB 增量。
  # 单个 [20-500GB]，步长：1-GB 增量。
  core_disk_size         = 400
  #  (可选) 有效值为 PrePaid, PostPaid，系统默认为 PostPaid。也可以从 PostPaid 转换为 PrePaid，支持从 v1.115.0+ 将 PrePaid 转换为 PostPaid。
  pay_type               = "PostPaid"
  # (可选) 0 或 [800, 100000000]，步长：10-GB 增量。0 表示 is_cold_storage = false。[800, 100000000] 表示 is_cold_storage = true。
  cold_storage_size      = 0
  # (可选，从 1.109.0 起可用) 立即删除开关。True: 立即删除，False: 延迟删除。无论设置为 true 还是 false，您都将无法找到集群。
  immediate_delete_flag  =  true
  # (可选) 有效值为 1, 2, 3, 4, 5, 6, 7, 8, 9, 12, 24, 36，仅在 pay_type = PrePaid 时有效，单位：月。12, 24, 36 表示 1, 2, 3 年。
  duration               = 1
  # (可选，从 1.73.0 起可用) 删除保护开关。True: 删除保护，False: 不做删除保护。如果您想删除集群，必须设置为 false。
  deletion_protection    = false
}

  2. 执行以下命令，初始化Terraform运行环境。

    terraform init

    返回如下信息，表示Terraform初始化成功。

    Initializing the backend...

Initializing provider plugins...
- Finding latest version of hashicorp/alicloud...
- Installing hashicorp/alicloud v1.234.0...
- Installed hashicorp/alicloud v1.234.0 (signed by HashiCorp)

Terraform has created a lock file .terraform.lock.hcl to record the provider
selections it made above. Include this file in your version control repository
so that Terraform can guarantee to make the same selections by default when
you run "terraform init" in the future.

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

  3. 创建执行计划，并预览变更。

    terraform plan

  4. 执行以下命令，创建HBase集群实例。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示创建HBase集群成功。

    Plan: 3 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

alicloud_vpc.vpc1: Creating...
alicloud_vpc.vpc1: Creation complete after 6s [id=vpc-m5ecf5pojlcjkolx7u***]
alicloud_vswitch.default: Creating...
alicloud_vswitch.default: Creation complete after 4s [id=vsw-m5ehryjeb8rs3bm56j***]
alicloud_hbase_instance.default: Creating...
alicloud_hbase_instance.default: Still creating... [10s elapsed]
alicloud_hbase_instance.default: Still creating... [20s elapsed]
alicloud_hbase_instance.default: Still creating... [30s elapsed]
alicloud_hbase_instance.default: Still creating... [40s elapsed]
alicloud_hbase_instance.default: Still creating... [50s elapsed]
alicloud_hbase_instance.default: Still creating... [1m0s elapsed]
alicloud_hbase_instance.default: Still creating... [1m10s elapsed]
alicloud_hbase_instance.default: Still creating... [1m20s elapsed]
...
alicloud_hbase_instance.default: Still creating... [16m30s elapsed]
alicloud_hbase_instance.default: Still creating... [16m40s elapsed]
alicloud_hbase_instance.default: Still creating... [16m50s elapsed]
alicloud_hbase_instance.default: Creation complete after 16m57s [id=ld-m5ezvi1qi8tkbu***]

Apply complete! Resources: 3 added, 0 changed, 0 destroyed.

  5. 验证结果 。

    执行terraform show命令
    登录HBase管理控制台

    您可以使用以下命令查询Terraform已创建的资源详细信息：

    terraform show

    image

    创建完成后，您可以登录HBase管理控制台，检查操作是否正确完成。image

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

 
variable "region" {
  default = "cn-qingdao"
}
provider "alicloud" {
  region = var.region
}
data "alicloud_hbase_zones" "default" {}
variable "instance_type" {
  default = "hbase.sn2.large"
}
variable "name" {
  default = "hbasetest"
}
# 创建 alicloud_vpc 资源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}
# 在 local.zone_id 地区创建 alicloud_vpc 资源下的 alicloud_vswitch 资源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = data.alicloud_hbase_zones.default.zones[0].id
}
resource "alicloud_hbase_instance" "default" {
  timeouts {
    create = "100m" # 给创建加上超时时间
  }
  # (必填) HBase 实例名称，长度必须为 2-128 个字符，只允许使用中文字符、英文字母、数字、句点 (.)、下划线 (_) 或短横线 (-)。
  name        = var.name
  #  (可选，ForceNew) 启动 HBase 实例的区域。
  zone_id                = data.alicloud_hbase_zones.default.zones[0].id
  # (可选，ForceNew) 
  vswitch_id             = alicloud_vswitch.default.id
  #  (可选，ForceNew，从 v1.185.0 起可用) VPC 的 ID。
  vpc_id                 = alicloud_vpc.vpc1.id
  #  (可选，ForceNew) 有效值为 "hbase/hbaseue/bds"。自 v1.73.0 之后支持的类型包括 hbaseue 和 bds。单个 HBase 实例需要设置 engine=hbase，core_instance_quantity=1。
  engine                 = "hbaseue"
  # (必填，ForceNew) HBase 主版本，hbase:1.1/2.0, hbaseue:2.0, bds:1.0，当前暂不支持其他引擎。
  engine_version         = "2.0"
  # (必填) 实例规格
  master_instance_type   = var.instance_type
  # (必填) 实例规格
  core_instance_type     = var.instance_type
  # (可选) 默认值为 2，范围为 [1-200]。若 core_instance_quantity > 1，则为集群实例；若 core_instance_quantity = 1，则为单个实例。
  core_instance_quantity = "2"
  #  (可选，ForceNew) 有效值为 cloud_ssd, cloud_essd_pl1, cloud_efficiency, local_hdd_pro, local_ssd_pro，``，local_disk 大小是固定的。当 engine=bds 时，无需设置磁盘类型（或空字符串）。
  core_disk_type         = "cloud_ssd"
  # (可选) 用户定义的 HBase 实例每个核心节点的存储，仅在 engine=hbase/hbaseue 时有效。Bds 引擎无需设置 core_disk_size，单位：GB。值范围：
  # 自定义存储空间，值范围：[20, 64000]。
  # 集群 [400, 64000]，步长：40-GB 增量。
  # 单个 [20-500GB]，步长：1-GB 增量。
  core_disk_size         = 400
  #  (可选) 有效值为 PrePaid, PostPaid，系统默认为 PostPaid。也可以从 PostPaid 转换为 PrePaid，支持从 v1.115.0+ 将 PrePaid 转换为 PostPaid。
  pay_type               = "PostPaid"
  # (可选) 0 或 [800, 100000000]，步长：10-GB 增量。0 表示 is_cold_storage = false。[800, 100000000] 表示 is_cold_storage = true。
  cold_storage_size      = 0
  # (可选，从 1.109.0 起可用) 立即删除开关。True: 立即删除，False: 延迟删除。无论设置为 true 还是 false，您都将无法找到集群。
  immediate_delete_flag  =  true
  # (可选) 有效值为 1, 2, 3, 4, 5, 6, 7, 8, 9, 12, 24, 36，仅在 pay_type = PrePaid 时有效，单位：月。12, 24, 36 表示 1, 2, 3 年。
  duration               = 1
  # (可选，从 1.73.0 起可用) 删除保护开关。True: 删除保护，False: 不做删除保护。如果您想删除集群，必须设置为 false。
  deletion_protection    = false
}

如果您想体验更多完整示例，请前往更多完整示例中对应产品的文件夹查看。

上一篇：HBase（云数据库）下一篇：Kafka（云消息队列）
  • 本页导读 （1）
  • 前提条件
  • 使用的资源
  • 使用Terraform创建HBase集群
  • 清理资源
  • 完整示例
  • 示例代码
  • 相关文档