AI 助理
备案控制台
官方文档
输入文档关键字查找
首页 Terraform 实践教程 Kafka（云消息队列） 通过 Terraform 为SASL用户授权

通过 Terraform 为SASL用户授权

更新时间：
我的收藏

云消息队列 Kafka 版的专业版实例支持使用访问控制列表（ACL）来管理SASL用户对主题和消费组的访问权限。利用Terraform，您可以方便地将ACL权限设置融入基础设施即代码（IaC）流程，例如，通过编写Terraform配置文件来指定用户权限，然后执行Terraform命令来自动应用配置。

说明

本教程所含示例代码支持一键运行，您可以直接运行代码。一键运行

前提条件

  • 由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式请参见创建RAM用户和创建AccessKey。

  • 通过RAM授权，阿里云用户可以有效地管理其云资源访问权限，适应多用户协同工作的需求，并且能够按需为用户分配最小权限，避免权限过大导致的安全漏洞‌。具体操作方式请参见为RAM用户授权。

    {
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "ecs:CreateSecurityGroup",
                "ecs:ModifySecurityGroupPolicy",
                "ecs:DescribeSecurityGroups",
                "ecs:ListTagResources",
                "ecs:DeleteSecurityGroup",
                "ecs:DescribeSecurityGroupAttribute",
                "ecs:AuthorizeSecurityGroup",
                "ecs:RevokeSecurityGroup"
            ],
            "Resource": "*"
        },
        {
            "Action": "alikafka:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "connector.alikafka.aliyuncs.com",
                        "instanceencryption.alikafka.aliyuncs.com",
                        "alikafka.aliyuncs.com",
                        "etl.alikafka.aliyuncs.com"
                    ]
                }
            }
        }
    ]
}

  • 准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。

    • 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。

    • Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。

    • 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

使用的资源

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行释放或退订。

创建SASL用户并添加权限

本示例在华南1（深圳）地域下创建Topic、SASL用户，并为此用户添加Topic的可写权限，Topic名称为example-topic，SASL用户名为example。

  1. 创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下代码复制到main.tf中。

    • 创建前置资源。

      说明

      实例类型为专业版并且已开启ACL的实例才可以创建SASL用户。

      variable "name" {
  default = "tf-example"
}

variable "region" {
  default = "cn-shenzhen"
}

data "alicloud_zones" "default" {
  available_resource_creation = "VSwitch"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

provider "alicloud" {
  region = var.region
}

resource "alicloud_vpc" "default" {
  vpc_name   = var.name
  cidr_block = "10.4.0.0/16"
}

resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "10.4.0.0/24"
  vpc_id       = alicloud_vpc.default.id
  zone_id      = data.alicloud_zones.default.zones.0.id
}

# 创建安全组。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

resource "alicloud_alikafka_instance" "default" {
  name            = "${var.name}-${random_integer.default.result}"
  partition_num   = 50
  disk_type       = "1"
  disk_size       = "500"
  deploy_type     = "5"
  io_max          = "20"
  spec_type       = "professional"
  service_version = "2.2.0"
  config          = "{\"enable.acl\":\"true\"}"
  vswitch_id      = alicloud_vswitch.default.id
  security_group  = alicloud_security_group.default.id
}

resource "alicloud_alikafka_topic" "default" {
  instance_id = alicloud_alikafka_instance.default.id
  topic       = "example-topic"
  remark      = "topic-remark"
}

resource "alicloud_alikafka_sasl_user" "default" {
  instance_id = alicloud_alikafka_instance.default.id
  username    = var.name
  password    = "tf_example123"
}

    • 在main.tf文件中增加resource "alicloud_alikafka_sasl_acl" "default"配置项。

      resource "alicloud_alikafka_sasl_acl" "default" {
  instance_id               = alicloud_alikafka_instance.default.id
  username                  = alicloud_alikafka_sasl_user.default.username
  acl_resource_type         = "Topic"
  acl_resource_name         = alicloud_alikafka_topic.default.topic
  acl_resource_pattern_type = "LITERAL"
  acl_operation_type        = "Write"
}

  2. 执行以下命令，初始化Terraform运行环境。

    terraform init

    返回如下信息，表示Terraform初始化成功。

    Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other

  3. 创建执行计划，并预览变更。

    terraform plan

  4. 执行以下命令，创建资源。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

    random_integer.default: Creating...
random_integer.default: Creation complete after 0s [id=****]
alicloud_vpc.default: Creating...
alicloud_vpc.default: Creation complete after 7s [id=vpc-****]
alicloud_security_group.default: Creating...
alicloud_vswitch.default: Creating...
alicloud_security_group.default: Creation complete after 1s [id=sg-****]
alicloud_vswitch.default: Creation complete after 4s [id=vsw-****]
alicloud_alikafka_instance.default: Creating...
alicloud_alikafka_instance.default: Still creating... [10s elapsed]
···
alicloud_alikafka_instance.default: Still creating... [4m20s elapsed]
alicloud_alikafka_instance.default: Creation complete after 4m22s [id=alikafka_post-cn-****]
alicloud_alikafka_sasl_user.default: Creating...
alicloud_alikafka_topic.default: Creating...
alicloud_alikafka_sasl_user.default: Creation complete after 3s [id=alikafka_post-cn-****:tf-example]
alicloud_alikafka_topic.default: Creation complete after 8s [id=alikafka_post-cn-****:example-topic]
alicloud_alikafka_sasl_acl.default: Creating...
alicloud_alikafka_sasl_acl.default: Still creating... [10s elapsed]
···
alicloud_alikafka_sasl_acl.default: Still creating... [1m0s elapsed]
alicloud_alikafka_sasl_acl.default: Creation complete after 1m1s [id=alikafka_post-cn-****:tf-example:Topic:example-topic:LITERAL:Write]

Apply complete! Resources: 8 added, 0 changed, 0 destroyed.

  5. 验证结果。

    执行terraform show命令

    执行terraform show查看SASL用户权限信息。

    terraform show
    # alicloud_alikafka_sasl_acl.default:
resource "alicloud_alikafka_sasl_acl" "default" {
    acl_operation_type        = "Write"
    acl_resource_name         = "example-topic"
    acl_resource_pattern_type = "LITERAL"
    acl_resource_type         = "Topic"
    host                      = "*"
    id                        = "alikafka_post-cn-****:tf-example:Topic:example-topic:LITERAL:Write"
    instance_id               = "alikafka_post-cn-****"
    username                  = "tf-example"
}

    登录云消息队列 Kafka 版控制台

    登录云消息队列 Kafka 版控制台，查看SASL用户权限信息。image

查询SASL用户权限

  1. 在上述main.tf文件中，增加data "alicloud_alikafka_sasl_users" "sasl_acls_ds"配置项，具体配置如下。

    data "alicloud_alikafka_sasl_acls" "sasl_acls_ds" {
  instance_id = "<Kafka实例ID>"
  username = "<SASL用户名称>"
  acl_resource_type = "<ACL资源类型>"
  acl_resource_name = "<ACL资源名称>"
  output_file = "saslAcls.txt"
}

  2. 创建执行计划，并预览变更。

    terraform plan

  3. 执行以下命令，创建资源。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

    random_integer.default: Refreshing state... [id=****]
data.alicloud_zones.default: Reading...
alicloud_vpc.default: Refreshing state... [id=vpc-****]
alicloud_security_group.default: Refreshing state... [id=sg-****]
data.alicloud_zones.default: Read complete after 2s [id=****]
alicloud_vswitch.default: Refreshing state... [id=vsw-****]
alicloud_alikafka_instance.default: Refreshing state... [id=alikafka_post-cn-****]
alicloud_alikafka_sasl_user.default: Refreshing state... [id=alikafka_post-cn-****:tf-example]
data.alicloud_alikafka_sasl_acls.sasl_acls_ds: Reading...
alicloud_alikafka_topic.default: Refreshing state... [id=alikafka_post-cn-****:example-topic]
data.alicloud_alikafka_sasl_acls.sasl_acls_ds: Read complete after 0s [id=0]
alicloud_alikafka_sasl_acl.default: Refreshing state... [id=alikafka_post-cn-****:tf-example:Topic:example-topic:LITERAL:Write]

No changes. Your infrastructure matches the configuration.

Terraform has compared your real infrastructure against your configuration and found no differences, so no changes are needed.

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

  4. 验证结果。执行terraform show查看Kafka SASL用户权限信息。

    terraform show
    # data.alicloud_alikafka_sasl_acls.sasl_acls_ds:
data "alicloud_alikafka_sasl_acls" "sasl_acls_ds" {
    acl_resource_name = "testTopic"
    acl_resource_type = "Topic"
    acls              = []
    id                = "0"
    instance_id       = "alikafka_post-cn-****"
    output_file       = "saslAcls.txt"
    username          = "tf-example"
}

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

variable "name" {
  default = "tf-example"
}

variable "region" {
  default = "cn-shenzhen"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

provider "alicloud" {
  region = var.region
}

data "alicloud_zones" "default" {
  available_resource_creation = "VSwitch"
}

resource "alicloud_vpc" "default" {
  vpc_name   = var.name
  cidr_block = "10.4.0.0/16"
}

resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "10.4.0.0/24"
  vpc_id       = alicloud_vpc.default.id
  zone_id      = data.alicloud_zones.default.zones.0.id
}

# 创建安全组。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

resource "alicloud_alikafka_instance" "default" {
  name            = "${var.name}-${random_integer.default.result}"
  partition_num   = 50
  disk_type       = "1"
  disk_size       = "500"
  deploy_type     = "5"
  io_max          = "20"
  spec_type       = "professional"
  service_version = "2.2.0"
  config          = "{\"enable.acl\":\"true\"}"
  vswitch_id      = alicloud_vswitch.default.id
  security_group  = alicloud_security_group.default.id
}

resource "alicloud_alikafka_topic" "default" {
  instance_id = alicloud_alikafka_instance.default.id
  topic       = "example-topic"
  remark      = "topic-remark"
}

resource "alicloud_alikafka_sasl_user" "default" {
  instance_id = alicloud_alikafka_instance.default.id
  username    = var.name
  password    = "tf_example123"
}

resource "alicloud_alikafka_sasl_acl" "default" {
  instance_id               = alicloud_alikafka_instance.default.id
  username                  = alicloud_alikafka_sasl_user.default.username
  acl_resource_type         = "Topic"
  acl_resource_name         = alicloud_alikafka_topic.default.topic
  acl_resource_pattern_type = "LITERAL"
  acl_operation_type        = "Write"
}

data "alicloud_alikafka_sasl_acls" "sasl_acls_ds" {
  instance_id       = alicloud_alikafka_instance.default.id
  username          = alicloud_alikafka_sasl_user.default.username
  acl_resource_type = "Topic"
  acl_resource_name = "testTopic"
  depends_on        = [alicloud_alikafka_sasl_acl.default]
}

相关文档

上一篇：通过 Terraform 管理 Kafka Consumer Group下一篇：MongoDB（云数据库MongoDB版）