使用Terraform创建ACK Serverless集群

• alicloud_eci_zones：查询ECI实例的可用区。

• alicloud_vpc：创建专有网络VPC。

• alicloud_vswitch：创建虚拟交换机（vSwitch）为VPC划分一个或多个子网。

• alicloud_security_group：创建安全组。

• alicloud_cs_serverless_kubernetes：创建一个ACK Serverless集群。

使用Terraform创建ACK Serverless集群

1. 创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下代码复制到main.tf中。

   provider "alicloud" {
     region = var.region_id
   }
   
   variable "region_id" {
     type    = string
     default = "cn-shenzhen"
   }
   
   variable "cluster_spec" {
     type    = string
     description = "The cluster specifications of kubernetes cluster,which can be empty. Valid values:ack.standard : Standard managed clusters; ack.pro.small : Professional managed clusters."
     default = "ack.pro.small"
   }
   
   variable "k8s_name_prefix" {
     description = "The name prefix used to create ASK cluster."
     default     = "ask-example"
   }
   
   variable "ack_version" {
     type        = string
     description = "Desired Kubernetes version. "
     default     = "1.31.1-aliyun.1"
   }
   
   # 默认资源名称。
   locals {
     k8s_name_ask = substr(join("-", [var.k8s_name_prefix, "ask"]), 0, 63)
     new_vpc_name = "tf-vpc-172-16"
     new_vsw_name = "tf-vswitch-172-16-0"
     new_sg_name = "tf-sg-172-16"
   }
   
   data "alicloud_eci_zones" "default" {}
   
   resource "alicloud_vpc" "vpc" {
     vpc_name   = local.new_vpc_name
     cidr_block = "172.16.0.0/12"
   }
   
   resource "alicloud_vswitch" "vsw" {
     vswitch_name = local.new_vsw_name
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = cidrsubnet(alicloud_vpc.vpc.cidr_block, 8, 8)
     zone_id      = data.alicloud_eci_zones.default.zones.0.zone_ids.1
   }
   
   resource "alicloud_security_group" "group" {
     name   = local.new_sg_name
     vpc_id = alicloud_vpc.vpc.id
   }
   
   resource "alicloud_cs_serverless_kubernetes" "serverless" {
     name                           = local.k8s_name_ask
     version                        = var.ack_version # 替换为您所需创建的集群版本。
     cluster_spec                   = var.cluster_spec
     vpc_id                         = alicloud_vpc.vpc.id
     vswitch_ids                    = split(",", join(",", alicloud_vswitch.vsw.*.id))
     new_nat_gateway                = true
     endpoint_public_access_enabled = true
     deletion_protection            = false
     security_group_id  = alicloud_security_group.group.id
     # 通过RRSA配置ServiceAccount。
     enable_rrsa = true
     time_zone               = "Asia/Shanghai"
     service_cidr            = "10.13.0.0/16"
     service_discovery_types = ["CoreDNS"]
   
     # tags
     tags = {
       "cluster" = "ack-serverless"
     }
     # addons
     addons {
       name = "nginx-ingress-controller"
       # 使用Internet。
       config = "{\"IngressSlbNetworkType\":\"internet\",\"IngressSlbSpec\":\"slb.s2.small\"}"
       # 如果使用Intranet, 配置如下。
       # config = "{\"IngressSlbNetworkType\":\"intranet\",\"IngressSlbSpec\":\"slb.s2.small\"}"
     }
     addons {
       name = "metrics-server"
     }
     addons {
       name = "knative"
     }
     addons {
       name = "managed-arms-prometheus"
     }
     addons {
       name = "logtail-ds"
       # 指定具体的sls_project_name
       # config = "{\"sls_project_name\":\"<YOUR-SLS-PROJECT-NAME>}\"}"
     }
   }

2. 执行如下命令，初始化Terraform运行环境。

   terraform init

   返回信息如下，Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 执行如下命令，创建执行计划。

   terraform plan

   返回如下信息，表示执行计划生成成功，您可以预览资源的详细信息。

   Refreshing Terraform state in-memory prior to plan...
   The refreshed state will be used to calculate this plan, but will not be
   persisted to local or remote state storage.
   ...
   Plan: 4 to add, 0 to change, 0 to destroy. 
   ...

4. 执行如下命令，创建集群。

   terraform apply

   在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示ACK集群创建成功。

   ...
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   ...
   alicloud_cs_serverless_kubernetes.serverless: Creation complete after 8m26s [id=************]
   
   Apply complete! Resources: 4 added, 0 changed, 0 destroyed.

5. 验证结果

   执行terraform show命令

   您可以使用以下命令查询Terraform已创建的资源详细信息。

   terraform show

   登录ACK控制台

   登录容器服务管理控制台，查看已创建的集群。