高可用虚拟IP（HaVip）

控制台

API

• 调用CreateHaVip创建 HaVip。

• 调用AssociateHaVip绑定 HaVip 和 ECS 实例或弹性网卡。

• 调用UnassociateHaVip解绑 HaVip 和 ECS 实例或弹性网卡。

• 调用DeleteHaVip删除 HaVip。

Terraform

Resource：alicloud_havip、alicloud_havip_attachment、alicloud_instance、alicloud_security_group、alicloud_security_group_rule

# 指定创建HaVip的地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定VPC的ID
variable "vpc_id" {
  default = "vpc-bp1k******" # 修改为VPC的实际ID
}

# 指定交换机ID
variable "vswitch_id" {
  default = "vsw-bp1y******" # 修改为交换机的实际ID
}

# 指定实例规格
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# 指定镜像ID
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# 创建HaVip
resource "alicloud_havip" "test_havip" {
  ha_vip_name = "test_havip_name"
  vswitch_id  = var.vswitch_id
  ip_address  = "192.168.0.24" # 从交换机网段内，指定HaVip的IP地址；若不指定，将由系统分配
}

# 创建安全组
resource "alicloud_security_group" "test_security_group" {
  security_group_name = "test_security_group_name"
  vpc_id              = var.vpc_id
}

# 创建安全组规则，需根据实际流量调整协议、访问来源与端口。
resource "alicloud_security_group_rule" "allow_vpc_tcp" {
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "8000/8000"
  priority          = 1
  security_group_id = alicloud_security_group.test_security_group.id
  cidr_ip           = "192.168.0.0/24"
}

# 创建主服务器 
resource "alicloud_instance" "test_master_instance" {
  instance_name        = "test_master_instance_name"
  vswitch_id           = var.vswitch_id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.test_security_group.id]
  user_data = base64encode(<<-EOT
    #!/bin/sh
    yum install keepalived -y

    printf '! Configuration File for keepalived
    vrrp_instance VI_1 {
        state MASTER            # 设置为主实例
        interface eth0          # 绑定VIP的网卡，本示例配置为eth0  
        virtual_router_id 51    # 主备集群的virtual_router_id；同一VPC下的不同主备集群需要配置不同的virtual_router_id
        nopreempt               # 设置非抢占模式
        priority 100            # 设置优先级，数字越大，优先级越高；本示例配置优先级为100，将本实例设置为主实例
        advert_int 1            # 心跳报文发送间隔，单位为秒。设置过小，易受网络抖动影响，可能发生频繁倒换和暂时双主（即脑裂）。设置过大，可能导致主实例故障后，主备切换时间长。
        authentication {
            auth_type PASS
            auth_pass 1111
        }
        unicast_src_ip 192.168.0.25     # 本实例的私网IP地址，本示例配置为192.168.0.25
        unicast_peer {
            192.168.0.26                # 对端实例的私网IP地址，本示例配置为192.168.0.26；如有多台备用ECS实例，需声明所有对端实例的IP。每个地址单独占一行，无需逗号或其他分隔符。
        }
        virtual_ipaddress {
            192.168.0.24                # 虚拟IP地址，配置为HaVip的IP地址，本示例为192.168.0.24
        }   
        garp_master_delay 1             # 当切为主实例后多久更新ARP缓存，单位为秒 
        garp_master_refresh 5           # 发送ARP报文的时间间隔，单位为秒 

        track_interface {
            eth0                        # 绑定VIP的网卡，本示例配置为eth0
        }
    }' > /etc/keepalived/keepalived.conf
    systemctl start keepalived
  EOT
  )                                           # 指定主服务器的初始化脚本，为主服务器安装keepalived
  private_ip           = "192.168.0.25"       # 指定主服务器的私网IP
  instance_charge_type = "PostPaid"           # 指定付费类型为按量付费
  spot_strategy        = "SpotWithPriceLimit" # 设置上限价格的抢占式实例
}

# 创建备服务器 
resource "alicloud_instance" "test_backup_instance" {
  instance_name        = "test_backup_instance_name"
  vswitch_id           = var.vswitch_id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.test_security_group.id]
  user_data = base64encode(<<-EOT
    #!/bin/sh
    yum install keepalived -y

    printf '! Configuration File for keepalived
    vrrp_instance VI_1 {
        state BACKUP            # 设置为备实例
        interface eth0          # 绑定VIP的网卡，本示例配置为eth0  
        virtual_router_id 51    # 主备集群的virtual_router_id；同一VPC下的不同主备集群需要配置不同的virtual_router_id
        nopreempt               # 设置非抢占模式
        priority 10             # 设置优先级，数字越大，优先级越高；本示例配置优先级为10，将本实例设置为备实例
        advert_int 1            # 心跳报文发送间隔，单位为秒。设置过小，易受网络抖动影响，可能发生频繁倒换和暂时双主（即脑裂）。设置过大，可能导致主实例故障后，主备切换时间长
        authentication {
            auth_type PASS
            auth_pass 1111
        }
        unicast_src_ip 192.168.0.26   # 本实例的私网IP地址，本示例配置为192.168.0.26
        unicast_peer {
            192.168.0.25          # 对端实例的私网IP地址，本示例配置为192.168.0.25。需声明所有对端实例的IP。每个地址单独占一行，无需逗号或其他分隔符。
        }
        virtual_ipaddress {
            192.168.0.24          # 虚拟IP地址，配置为HaVip的IP地址，本示例为192.168.0.24 
        }    
        garp_master_delay 1       # 当切为主实例后多久更新ARP缓存，单位为秒 
        garp_master_refresh 5     # 发送ARP报文的时间间隔，单位为秒 

        track_interface {
            eth0                  # 绑定VIP的网卡，本示例配置为eth0
        }
    }' > /etc/keepalived/keepalived.conf
    systemctl start keepalived
  EOT
  )                                           # 指定备服务器的初始化脚本，为备服务器安装keepalived
  private_ip           = "192.168.0.26"       # 指定备服务器的私网IP 
  instance_charge_type = "PostPaid"           # 指定付费类型为按量付费
  spot_strategy        = "SpotWithPriceLimit" # 设置上限价格的抢占式实例
}

# 绑定主服务器
resource "alicloud_havip_attachment" "test_havip_attachment" {
  ha_vip_id   = alicloud_havip.test_havip.id
  instance_id = alicloud_instance.test_master_instance.id # 指定HaVip关联的实例ID
}

# 绑定备服务器
resource "alicloud_havip_attachment" "test_havip_attachment_new" {
  ha_vip_id   = alicloud_havip.test_havip.id
  instance_id = alicloud_instance.test_backup_instance.id # 指定HaVip关联的实例ID
}

控制台

API

绑定 EIP 前，确保已调用AllocateEipAddress创建 EIP。

• 调用AssociateEipAddress绑定 HaVip 和 EIP。

• 调用UnassociateEipAddress解绑 HaVip 和 EIP。

Terraform

Resource：alicloud_eip_address、alicloud_eip_association

# 指定HaVip所在地域 
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定HaVip的ID
variable "havip_id" {
  default = "havip-8vb0******"  # 修改为HaVip的实际ID
}

# 创建EIP
resource "alicloud_eip_address" "test_eip" {
  address_name = "test_eip_name"
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# 绑定EIP
resource "alicloud_eip_association" "test_eip_havip_association" {
  allocation_id = alicloud_eip_address.test_eip.id
  instance_type = "HAVIP"
  instance_id   = var.havip_id # 指定HaVip的ID
}