VPC peering connection

Create a peering connection

1. Call the CreateVpcPeerConnection operation to create a VPC peering connection.

2. If the two VPCs belong to different accounts, use the accepter account to call the AcceptVpcPeerConnection operation to accept the VPC peering connection.

   The accepter can also call the RejectVpcPeerConnection operation to reject the VPC peering connection.

3. From each account, call the GetVpcPeerConnectionAttribute operation to query the CIDR block of the peer VPC.

4. From each account, call the CreateRouteEntry operation to create a route entry that points to the VPC peering connection.

Modify an inter-region peering connection

Call the ModifyVpcPeerConnection operation to modify the bandwidth or link type of an inter-region VPC peering connection.

Delete a peering connection

• Call the DeleteRouteEntry operation to delete the route entries that point to the VPC peering connection.

• Call the DeleteVpcPeerConnection operation to delete the VPC peering connection.

Reachability Analyzer

To use Reachability Analyzer to verify connectivity, call the following API operations in the following order:

1. CreateNetworkAnalysisPath

2. StartNetworkReachableAnalysis

3. GetNetworkReachableAnalysisResult

Same-account peering connection

Resources: alicloud_vpc_peer_connection, alicloud_route_entry

Data Sources: alicloud_account

# The account that owns the VPC.
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # The region of the requester VPC.
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" # The region of the accepter VPC. This can be the same as the requester region.
}

# The ID of the requester VPC.
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# The ID of the accepter VPC.
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# Create a VPC peering connection.
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # The ID of the requester VPC.
  accepting_ali_uid    = data.alicloud_account.default.id # The ID of the accepter account.   
  accepting_region_id  = "cn-beijing"                     # The region of the accepter VPC.
  accepting_vpc_id     = var.accepting_vpc_id             # The ID of the accepter VPC.
  bandwidth            = 1024                             # Bandwidth in Mbps. Configurable only for inter-region connections.
  link_type            = "Gold"                           # Link type. Configurable only for inter-region connections.
}

# Configure a route for the requester VPC.
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # The ID of the route table associated with the vSwitch of the requester instance.
  destination_cidrblock = "172.16.0.0/12"             # The CIDR block of the accepter VPC.
  nexthop_type          = "VpcPeer"                   # The next hop is a VPC peering connection.
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Configure a route for the accepter VPC.
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # The ID of the route table associated with the vSwitch of the accepter instance.
  destination_cidrblock = "10.0.0.0/8"                # The CIDR block of the requester VPC.
  nexthop_type          = "VpcPeer"                   # The next hop is a VPC peering connection.
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Cross-account peering connection

Resources: alicloud_vpc_peer_connection, alicloud_vpc_peer_connection_accepter, alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # The region of the requester VPC. 
}

# The region of the accepter VPC. This can be the same as the requester region.
variable "accepting_region" {
  default = "cn-beijing"
}

# The ID of the accepter account.
variable "accepting_uid" {
  default = "1234******"
}

# The AccessKey ID of the accepter account.
variable "access_key_id" {
  description = "The AccessKey ID to manage your infrastructure"
}
# The AccessKey secret of the accepter account.
variable "access_key_secret" {
  description = "The AccessKey Secret to manage your infrastructure"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# The ID of the requester VPC.
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# The ID of the accepter VPC.
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# Create a VPC peering connection.
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # The ID of the requester VPC.
  accepting_ali_uid    = var.accepting_uid    # The ID of the accepter account.   
  accepting_region_id  = var.accepting_region # The region of the accepter VPC.
  accepting_vpc_id     = var.accepting_vpc_id # The ID of the accepter VPC.
  bandwidth            = 1024                 # Bandwidth in Mbps. Configurable only for inter-region connections.
  link_type            = "Gold"               # Link type. Configurable only for inter-region connections.
}

# The accepter accepts the peering connection request.
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Configure a route for the requester VPC.
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # The ID of the route table associated with the vSwitch of the requester instance.
  destination_cidrblock = "192.168.0.0/24" # The CIDR block of the accepter VPC.
  nexthop_type          = "VpcPeer"        # The next hop is a VPC peering connection.
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Configure a route for the accepter VPC.
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # The ID of the route table associated with the vSwitch of the accepter instance.
  destination_cidrblock = "172.16.0.0/12"  # The CIDR block of the requester VPC.
  nexthop_type          = "VpcPeer"        # The next hop is a VPC peering connection.
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Peering connection monitoring

1. Go to VPC Console - VPC Peering Connections. At the top of the page, select the region where the VPC is located.

2. For the target inter-region VPC peering connection, click the icon in the Monitor column to view metrics such as traffic, bandwidth, and packet loss.

CloudMonitor alerts

1. Go to CloudMonitor Console - Alert Rules and click Create Alert Rule.

2. Configure thresholds for each alert level for the VPC peering connection metrics. When a metric crosses its threshold, the specified Alert Contact Group receives a notification. You can also view the alert timeline by clicking Alert History in the Actions column of the alert rule.

3. In the Actions column of the target alert rule, you can Modify, Disable, or Delete the rule.