VPC对等连接

创建对等连接

1. 调用CreateVpcPeerConnection创建VPC对等连接。

2. 两端VPC属于不同账号时，需使用接收端账号调用AcceptVpcPeerConnection接受VPC对等连接。

   接收端可以调用RejectVpcPeerConnection拒绝VPC对等连接。

3. 使用两端 VPC 所属账号，分别调用GetVpcPeerConnectionAttribute查询两端VPC的网段。

4. 使用两端 VPC 所属账号，分别调用CreateRouteEntry创建指向对等连接的路由条目。

修改跨地域对等连接

调用ModifyVpcPeerConnection修改跨地域VPC对等连接的带宽或链路类型。

删除对等连接

• 调用DeleteRouteEntry删除指向对等连接的路由条目。

• 调用DeleteVpcPeerConnection删除VPC对等连接。

路径分析

依次调用以下API来使用路径分析校验连通性。

1. CreateNetworkPath - 创建网络分析路径

2. CreateNetworkReachableAnalysis - 创建网络可达性分析任务

3. GetNetworkReachableAnalysis - 获取网络可达性分析任务结果

同账号对等连接

Resources：alicloud_vpc_peer_connection、alicloud_route_entry

Data Sources：alicloud_account

# VPC所属账号
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" #发起端VPC所属地域。
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" #接收端地域。可以和发起端地域相同，需要根据接收端VPC所属地域配置。
}

# 发起端VPC ID
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# 接收端VPC ID
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# 创建VPC对等连接
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # 发起端VPC ID
  accepting_ali_uid    = data.alicloud_account.default.id # 接收端账号 ID   
  accepting_region_id  = "cn-beijing"                     # 接收端VPC所属地域
  accepting_vpc_id     = var.accepting_vpc_id             # 接收端VPCID
  bandwidth            = 1024                             # 带宽，单位：Mbps。仅发起端地域和接收端地域不同时，可以配置。
  link_type            = "Gold"                           # 链路类型，仅发起端地域和接收端地域不同时，可以配置。
}

# 为发起端VPC配置路由
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # 发起端实例所属交换机绑定的路由表
  destination_cidrblock = "172.16.0.0/12"             # 接收端VPC网段
  nexthop_type          = "VpcPeer"                   # 下一跳为VPC对等连接
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 为接收端VPC配置路由
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # 接收端实例所属交换机绑定的路由表
  destination_cidrblock = "10.0.0.0/8"                # 发起端VPC网段
  nexthop_type          = "VpcPeer"                   # 下一跳为VPC对等连接
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

跨账号对等连接

Resources：alicloud_vpc_peer_connection、alicloud_vpc_peer_connection_accepter、alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" #发起端地域 
}

#接收端地域。可以和发起端地域相同，需要根据接收端VPC所属地域配置。
variable "accepting_region" {
  default = "cn-beijing"
}

#接收端账号
variable "accepting_uid" {
  default = "1234******"
}

#接收端账号AK
variable "access_key_id" {
  description = "The AccessKey ID for operating your infrastructure"
}
#接收端账号SK
variable "access_key_secret" {
  description = "The AccessKey Secret for operating your infrastructure"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# 发起端VPC ID
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# 接收端VPC ID
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# 创建VPC对等连接
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # 发起端VPC ID
  accepting_ali_uid    = var.accepting_uid    # 接收端账号ID   
  accepting_region_id  = var.accepting_region # 接收端地域
  accepting_vpc_id     = var.accepting_vpc_id # 接收端VPC ID
  bandwidth            = 1024                 # 带宽，单位：Mbps。仅发起端地域和接收端地域不同时，可以配置。
  link_type            = "Gold"               # 链路类型，仅发起端地域和接收端地域不同时，可以配置。
}

# 接收端接受对等连接请求
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 为发起端VPC配置路由
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # 发送端实例所属交换机绑定的路由表
  destination_cidrblock = "192.168.0.0/24" # 接收端VPC网段
  nexthop_type          = "VpcPeer"        # 下一跳为VPC对等连接
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 为接收端VPC配置路由
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # 接收端实例所属交换机绑定的路由表
  destination_cidrblock = "172.16.0.0/12"  # 发起端VPC网段
  nexthop_type          = "VpcPeer"        # 下一跳为VPC对等连接
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

对等连接监控

1. 前往专有网络控制台 - VPC对等连接，在页面上方选择VPC所在的地域。

2. 单击目标跨地域VPC对等连接实例监控列的图标，查看流量带宽与丢包情况等监控信息。

云监控告警

1. 前往云监控控制台 - 报警规则，单击创建报警规则。

2. 为VPC对等连接的监控指标项配置各报警级别的阈值，当相应指标达到阈值后，报警联系人组将接收到报警通知，也可以在目标报警规则的操作列，点击报警历史查看报警时间线。

3. 在目标报警规则的操作列，修改/禁用/删除规则。